ListView Control Tutorial-02

Introduction.

Continued from last week's ActiveX ListView Control Tutorial-01.

In this session, we will learn how to search for specific rows and column values in the ListView control and display the results on a Label control within the form. This feature is useful when working with large volumes of data. We will also explore the use of certain ListView property settings.

To begin, we will look at how easily columns can be rearranged in the ListView control—similar to how we do it in Access Datasheet View. For this purpose, additional controls such as Textboxes, Comboboxes, Command Buttons, and Labels have been added to the form, making the selection of search parameters and the display of search results more convenient.

For demonstration, I have slightly modified last week’s sample data. The first column values are now sourced from the Employees table of the Northwind sample database. A query was created to join the LastName and FirstName fields under the alias Student, while the EmployeeID field is used as the Key (e.g., X01, X02, and so on).

Before moving on to search operations, let us first explore how to rearrange columns in the ListView control using the drag-and-drop method.

Note: If you have not visited the earlier tutorial page and would like to continue directly with this session, then download the Demo database from the ListView Control Tutorial-01 page. Unzip the file, open the database, and you will find the demo form ready in Normal View.

Open your database with the previous session’s demo form (or the one you created) and switch it to Normal View.

Now, let us try dragging and moving a column from the middle of the list—for example, the Weight column—and dropping it in place of the Age column. The expected result is that the Age column should shift to the right, making room for the incoming column.

Move the mouse pointer over the Weight column header and click while holding down the left mouse button. You will notice that the column header moves slightly downward when the button is pressed. Now, drag the column to the left and drop it onto the Age column header.

At this point, you will see that nothing happens. This is because we have not yet enabled this feature in the property settings. In fact, this is the only change required to make the feature work.

To enable it:

1. Switch the form to Design View.

2. Right-click on the ListView control, highlight the ListViewCtrl Object option, and select Properties.



3. On the Properties window, you will find the option AllowColumnReorder on the right side. Place a check mark to enable it, then click Apply, and click the OK button to close the Properties window.

4. Now, repeat the drag-and-drop steps explained earlier and observe the result. This simple setting is all that’s required to enable column reordering in the ListView control.

5. You may be asking: What about rearranging rows?
   Unlike columns, row reordering requires additional programming using event procedures—similar to the drag-and-drop techniques we implemented earlier in the TreeView control. We will cover that part later in this tutorial series.

6. For now, feel free to experiment by moving any column, even the first column, to any position you like.

Note: Before dropping the source column, ensure that the target column is fully covered by the highlighted frame of the incoming column. If not, the column may shift to the next position on the right instead of replacing the intended target.

---

Next: Searching for Information in the ListView

Now, let’s move on to learning how to quickly search for information within the ListView—especially useful when working with large volumes of data.

For this purpose, we have added a subroutine to the Tutorial-01 module. This subroutine loads the column header names into a ComboBox on the form, which is displayed with a red background for visibility. The selected column name will be used to search and retrieve specific values (such as Age, Height, Weight, or Class) for a student.

New VBA Code Added to the Form’s Class Module

A new VBA procedure has been added to the Class Module of last week’s Tutorial Form.

This procedure populates the txtColCombo ComboBox with a list of column header labels (field names). These labels correspond to the data fields in the ListView, such as Age, Height, Weight, or Class.

During the search-and-find operation, one of these column values can be selected to retrieve the corresponding detail for a student, along with the student’s name.

Private Sub txtColCombo()
'Column Header List Combo
Dim lvwColHead As MSComctlLib.ColumnHeader
Dim cboName As ComboBox

Set cboName = Me.txtCol
cboName.RowSourceType = "Value List"

For Each lvwColHead In lvwList.ColumnHeaders
    If lvwColHead.Index = 1 Then
        'Nothing
    Else
        cboName.AddItem lvwColHead.Text
    End If
Next
'cboName.DefaultValue = "=txtCol.Column(0, 0)"

Set lvwColHead = Nothing
Set cboName = Nothing
End Sub

The ComboBox will not have a default value for the column header name. If a column is selected, the corresponding value for the student will be displayed in the large Label below the student’s name. If left blank, the search operation will return only the student’s name.

The search operation is flexible and fast, supporting two main methods:

1. Search by providing text – The search text can come from any column, either as a full match or as a partial string from the left. Since each row in the ListView control has two types of object members—ListItem (first column) and ListSubItems (remaining columns)—the search operation treats these separately.

2. Search options via an option group – Next to the search-text input TextBox, an option group with two checkboxes allows you to choose where to search:

   • First option (default): Searches the first column (ListItem) for the given text.

   • Second option: Searches within the ListSubItem columns.

Note: Rearranging columns affects only their visual position, not the object type. Dragging a ListSubItem into the first column does not convert it into a ListItem.

To retrieve a value from a specific column, select the column name from the ComboBox located below the search-text TextBox. For example, if you want to find a student’s Height, select Height from the ComboBox.

After setting the search criteria, click the Find Item Command Button. If the search is successful, the result will appear in the large Label control below the button.

The [Find Item] Command Button Click.

Calls the SearchAndFind() Procedure.

Private Sub SearchAndFind()
'Find by Student Name
Dim lstItem As MSComctlLib.ListItem
Dim strFind As String
Dim strColName As String
Dim strColVal As String
Dim j As Integer
Dim intOpt As Integer
Dim msgText As String

Me.Refresh
intOpt = Me.Opts


strFind = Nz(Me![txtFind], "")
strColName = Nz(Me![txtCol], "")

Select Case intOpt
    Case 1
        Set lstItem = lvwList.FindItem(strFind, , , lvwPartial)
    
        If Not lstItem Is Nothing Then
            j = lstItem.Index
            'format the display text
            msgText = lvwList.ColumnHeaders.Item(1).Text
            msgText = msgText & " : " & lstItem.Text & vbCr & vbCrLf
        Else
            MsgBox "Text '" & strFind & "' Not Found!", vbOKOnly + vbCritical, "cmdFind_Click()"
            Exit Sub
        End If
    Case 2
        Set lstItem = lvwList.FindItem(strFind, lvwSubItem, , lvwPartial)
        If Not lstItem Is Nothing Then
       'format the display text
            j = lstItem.Index
            msgText = lvwList.ColumnHeaders.Item(1).Text
            msgText = msgText & ": " & lstItem.Text & vbCr & vbCrLf
        Else
            MsgBox strFind & " Not Found!", vbOK + vbCritical, "cmdFind_Click()"
            Exit Sub
        End If
End Select

        If Len(strColName) = 0 Then 'If column name is not selected
            GoTo nextStep
        Else
            'Get the column value
            strColVal = GetColVal(lstItem, strColName)
            msgText = msgText & String(8 - (Len(strColName)), " ") & _
            strColName & ": " & Nz(strColVal, "")
        End If
nextStep:

If Len(msgText) > 0 Then 'assign to form label
    lvwList.ListItems.Item(j).Selected = True
    lblMsg.caption = msgText
End If

End Sub

At the beginning of the program, the Student Name and the optional Column Name are copied from their respective TextBoxes into the variables strFind and strColName, following validation checks.

Note: The Column Name ComboBox has its Not-in-List property set to Yes. This means you may either select a valid value from the list, type it in, or leave it blank. However, if you type in a value that does not exist in the list, it will not be accepted.

Depending on the selected search option (1 – ListItem or 2 – ListSubItem), the scan process is directed to the appropriate object(s).

Using either method, the program locates the ListItem object (row) that contains the search text. The Index value of the ListItem is then saved in the variable J for later use in the program.

Note: The ListView control automatically assigns index numbers when items are first populated.

Once found, the ListItem.Text value is retrieved. This value is combined with the first column header’s text (for example, Student: Robert King) and stored in the MsgText string, which is then displayed in the Label control on the form.

If a column header name is selected in the ComboBox, the program calls the GetColVal() function, passing the ListItem object and the selected column header text as parameters. This feature is especially useful for retrieving additional details about a student, such as their Height, directly from the record.

The GetColVal() Function VBA Code.

Private Function GetColVal(lvwItem As MSComctlLib.ListItem, ByVal colName As String) As String
Dim i As Integer
Dim strVal As String
    'first column is student name
    'check for column value from 2nd column onwards
    For i = 2 To lvwList.ColumnHeaders.Count
        If lvwList.ColumnHeaders(i).Text = colName Then 'if col name matches
            strVal = lvwItem.ListSubItems.Item(i - 1).Text 'get column value
            Exit For 'No further scanning required
        End If
    Next
GetColVal = strVal 'return the retrieved the value
End Function

The GetColVal() function requires two parameters:

1. The ListItem object, which contains the student’s name.

2. The Column Name to be retrieved.

The student’s details—such as Age, Height, Weight, and Class—are stored in the ListItem.ListSubItems collection. The function scans through the lvwList.ColumnHeader values to locate the matching column name.

Once a match is found, the corresponding column index is used to retrieve the value from the ListSubItems object, which is then returned to the calling procedure.

The [Find By Key] Command Button Click Event Procedure.

We have introduced another method to find a Student’s Name (or related information) by using the Unique Key Value assigned to a list item at the time of creating the list.

Although assigning a Key is optional, it is always recommended to add a Unique Key String Value (note: the key must begin with an alphabet character). This approach makes searching more efficient.

For example, when dealing with personal identification records, the following can serve as the Key:

• Social Security Number

• National Identity Card Number

• Passport Number

• Driving License Number

Using such identifiers as the ListItem Key makes it much faster and easier to locate a record compared to the conventional search-by-text method.

The cmdKey_Click() Event Procedure.

Calls FindByKey() Subroutine.

Private Sub FindByKey()
Dim colHeader As MSComctlLib.ColumnHeader
Dim lvItem As MSComctlLib.ListItem
Dim lvKeyVal As String
Dim lvColName As String
Dim txt As String
Dim msgText As String
Dim varcolVal As Variant

lvKeyVal = UCase(Nz(Me!txtKey, ""))
lvColName = Nz(Me!txtCol, "")

If len(lvKeyVal) > 0 then
On Error Resume Next 
Set lvItem = lvwList.ListItems.Item(lvKeyVal) 'get the item by Key
If Err > 0 Then
    Err.Clear
    MsgBox "Key Value: '" & lvKeyVal & "' Not Found!", vbOKOnly + vbCritical, "cmdKey_Click()"
    On Error GoTo 0
    Exit Sub
End If
Else
	MsgBox "Please Provide a Valid Key-Value!",vbOKOnly + vbCritical, "cmdKey_Click()"
    Exit Sub
End If

txt = lvItem.Text 'get the student name
'format message text
msgText = lvwList.ColumnHeaders.Item(1).Text & " : "
msgText = msgText & txt & vbCr & vbCrLf

If Len(lvColName) > 0 Then 'if column name is given
    varcolVal = GetColVal(lvItem, lvColName) 'get column val of student
    msgText = msgText & String(8 - Len(lvColName), " ") & lvColName & ": " & varcolVal ' add it to display
End If

lvItem.Selected = True 'highlight the item on form
Me.lblMsg.caption = msgText 'assign details to form Label
End Sub

As shown in the subroutine, we can directly locate the ListItem containing the Student’s name by using the Key value in a single statement:

Set lvItem = lvwList.ListItems.Item(xKeyVal)

The next line retrieves the ListItem.Text (the Student’s name) into the variable txt. The following two lines then build the message string by inserting the Student’s name into the variable msgText.

Next, an If…Then statement checks whether a Column Name has been entered in the ComboBox control. If a valid column is found, the program calls the GetColVal() function with the appropriate parameters to retrieve the value from that column. The returned value is stored in the variable varColVal and passed back to the calling procedure.

Finally, the Column Name and the retrieved value are appended to the msgText string, which is then displayed in the Label control on the Form.

The next statement highlights the Student’s record row as a visual cue that the searched item has been found. At the same time, the value stored in msgText is displayed in the Label control by setting its Caption property on the Form.

The Full VBA Code on the Form Module.

Option Compare Database
Option Explicit

Dim lvwList As MSComctlLib.ListView 'ListView Control
Dim lvwItem As MSComctlLib.ListItem '
Dim ObjImgList As MSComctlLib.ImageList
Const prfx As String = "K"

Private Sub Form_Load()
    Call LoadListView
    Call txtColCombo
End Sub

Private Function LoadListView()
'Populate the ListView control with Student Details
Dim db As DAO.Database
Dim rst As DAO.Recordset
Dim intCounter As Integer
Dim strKey As String

'Assign ListView Control on Form to lvwList Object
 Set lvwList = Me.ListView1.Object
 
With lvwList
    .AllowColumnReorder = True
    .Enabled = True
    .Font = "Verdana"
    .Font.Bold = True
    .Font.Size = 9
    .ForeColor = vbBlack
    .BackColor = vbWhite
 End With
 
 'Create Column Headers for ListView
 With lvwList
    .ColumnHeaders.Clear 'initialize header area
    
   'Syntax: .ColumnHeaders.Add Index, Key, Text, Width, Alignment, Icon
    .ColumnHeaders.Add , , "Student", 2500
    .ColumnHeaders.Add , , "Age", 1200
    .ColumnHeaders.Add , , "Height", 1200
    .ColumnHeaders.Add , , "weight", 1200
    .ColumnHeaders.Add , , "Class", 1200
    
 End With
 
 'Initialize ListView Control
  While lvwList.ListItems.Count > 0
        lvwList.ListItems.Remove (1)
  Wend

'Student Names and Ids are taken from Employees Table
'through the StudentQ Query.
Set db = CurrentDb
Set rst = db.OpenRecordset("StudentQ", dbOpenDynaset)

With lvwList
    Do While Not rst.EOF And Not rst.BOF
        intCounter = rst![EmployeeID]
        strKey = "X" & Format(intCounter, "00") 'Key Value sample: X01
        
    'Syntax: .ListItems.Add(Index, Key, Text, Icon, SmallIcon)
        Set lvwItem = .ListItems.Add(, strKey, rst![Student])
        
        With lvwItem
    'Syntax: .Add Index,Key,Text,Report Icon,TooltipText
            .ListSubItems.Add , strKey & CStr(intCounter), CStr(5 + intCounter)
            .ListSubItems.Add , strKey & CStr(intCounter + 1), CStr(135 + intCounter)
            .ListSubItems.Add , strKey & CStr(intCounter + 2), CStr(40 + intCounter)
            .ListSubItems.Add , strKey & CStr(intCounter + 3), ("Class:" & Format(intCounter, "00"))

       End With
        rst.MoveNext
    Loop
rst.Close
Set rst = Nothing
Set db = Nothing
Set lvwItem = Nothing
End With
lvwList.Refresh

End Function


Private Sub cmdClose_Click()
   DoCmd.Close acForm, Me.Name
End Sub

Private Sub cmdFind_Click()
Call SearchAndFind

End Sub

Private Sub cmdKey_Click()
Call FindByKey
End Sub

Private Function GetColVal(lvwItem As MSComctlLib.ListItem, ByVal colName As String) As String
Dim i As Integer
Dim strVal As String
    'first column is student name
    'check for column value from 2nd column onwards
    For i = 2 To lvwList.ColumnHeaders.Count
        If lvwList.ColumnHeaders(i).Text = colName Then 'if col name matches
            strVal = lvwItem.ListSubItems.Item(i - 1).Text 'get column value
            Exit For 'No further scanning required
        End If
    Next
GetColVal = strVal 'return the retrieved the value
End Function



Private Sub txtColCombo()
'Column Header List Combo
Dim lvwColHead As MSComctlLib.ColumnHeader
Dim cboName As ComboBox

Set cboName = Me.txtCol
cboName.RowSourceType = "Value List"

For Each lvwColHead In lvwList.ColumnHeaders
    If lvwColHead.Index = 1 Then
        'Nothing
    Else
        cboName.AddItem lvwColHead.Text
    End If
Next
'cboName.DefaultValue = "=txtCol.Column(0, 0)"

Set lvwColHead = Nothing
Set cboName = Nothing
End Sub


Public Sub SearchAndFind()
'Find by Student Name
Dim lstItem As MSComctlLib.ListItem
Dim strFind As String
Dim strColName As String
Dim strColVal As String
Dim j As Integer
Dim intOpt As Integer
Dim msgText As String

Me.Refresh
intOpt = Me.Opts

strFind = Nz(Me![txtFind], "")
strColName = Nz(Me![txtCol], "")

Select Case intOpt
    Case 1
        Set lstItem = lvwList.FindItem(strFind, , , lvwPartial)
        If Not lstItem Is Nothing Then
            j = lstItem.Index
            'format the display text
            msgText = lvwList.ColumnHeaders.Item(1).Text
            msgText = msgText & " : " & lstItem.Text & vbCr & vbCrLf
        Else
           MsgBox "Text '" & strFind & "' Not Found in the List!", vbOKOnly + vbCritical, "cmdFind_Click()"
        Exit Sub
        End If
    Case 2
        Set lstItem = lvwList.FindItem(strFind, lvwSubItem, , lvwPartial)
        If Not lstItem Is Nothing Then
       'format the display text
            j = lstItem.Index
            msgText = lvwList.ColumnHeaders.Item(1).Text
            msgText = msgText & ": " & lstItem.Text & vbCr & vbCrLf
        Else
            MsgBox strFind & " Not Found!", vbOK + vbCritical, "cmdFind_Click()"
            Exit Sub
        End If
End Select

        If Len(strColName) = 0 Then 'If column name is not selected
            GoTo nextStep
        Else
            'Get the column value
            strColVal = GetColVal(lstItem, strColName)
            msgText = msgText & String(8 - (Len(strColName)), " ") & _
            strColName & ": " & Nz(strColVal, "")
        End If
nextStep:

If Len(msgText) > 0 Then 'assign to form label
    lblMsg.caption = msgText
    lvwList.ListItems.Item(j).Selected = True
End If
End Sub

Public Sub FindByKey()
Dim colHeader As MSComctlLib.ColumnHeader
Dim lvItem As MSComctlLib.ListItem
Dim lvKeyVal As String
Dim lvColName As String
Dim txt As String
Dim msgText As String
Dim varcolVal As Variant


lvKeyVal = UCase(Nz(Me!txtKey, ""))
lvColName = Nz(Me!txtCol, "")

On Error Resume Next
If Len(lvKeyVal) > 0 Then
Set lvItem = lvwList.ListItems.Item(lvKeyVal) 'get the item by Key
    If Err > 0 Then
        Err.Clear
        MsgBox "Key Value: '" & lvKeyVal & "' Not Found!", vbOKOnly + vbCritical, "cmdKey_Click()"
       On Error GoTo 0
        Exit Sub
    End If
Else
    MsgBox "Please Provide a Valid Key-Value!", vbOKOnly + vbCritical, "cmdKey_Click()"
    Exit Sub
End If

txt = lvItem.Text 'get the student name
'format message text
msgText = lvwList.ColumnHeaders.Item(1).Text & " : "
msgText = msgText & txt & vbCr & vbCrLf

If Len(lvColName) > 0 Then 'if column name is given
    varcolVal = GetColVal(lvItem, lvColName) 'get column val of student
    msgText = msgText & String(8 - Len(lvColName), " ") & lvColName & ": " & varcolVal ' add it to display
End If

lvItem.Selected = True 'highlight the item on form
Me.lblMsg.caption = msgText 'assign details to form Label
End Sub

Download the Demo Database from the following Link:

LVTutorial02.zip

1. Microsoft TreeView Control Tutorial
2. Creating an Access Menu with a TreeView Control
3. Assigning Images to TreeView Nodes
4. Assigning Images to TreeView Nodes-2
5. TreeView Control Checkmark Add Delete
6. TreeView ImageCombo Drop-down Access
7. Re-arrange TreeView Nodes By Drag and Drop
8. ListView Control with MS-Access TreeView
9. ListView Control Drag Drop Events
10. TreeView Control With Sub-Forms

Read More

Activex ListView Control Tutorial-01

Introduction.

In Microsoft Access, the ListBox control is often used to display a few columns of data, making it easy to locate and select items. Its data source may be entered directly into the Row Source property as a value list, or it can be loaded dynamically from a table or query.

The ComboBox control, by contrast, keeps its list hidden until the user clicks to expand it and make a selection. Both of these are standard Access controls on forms.

There is also another familiar list-style control that we encounter frequently in Access: the Datasheet View. Whether records are displayed from a table or query, the datasheet presents them as a large, scrollable list in tabular form.

In addition to these built-in controls, Microsoft Access also allows us to use ActiveX controls. A common example is the Microsoft Common Dialog Control (often used for file browsing).

The focus of this topic, however, is the Windows ListView control. You can think of it as very similar to Windows Explorer: it can display items as large icons, small icons, a simple list, or in a detailed view with multiple columns. Data from an Access table or query can be loaded into the ListView, giving you the ability to:

• Rearrange columns or rows,

• Sort items interactively,

• Display images next to items,

• Present records in a more flexible, customizable layout.

This control is widely used in other programming environments such as VB6, VB.NET, and C#. In this article, we will explore how it can be integrated into a Microsoft Access database.

Below is a simple ListView demo screen displaying sample data:

We will use the image-like display shown earlier as the starting point for this ListView Control tutorial. With just a few lines of VBA code, we have uploaded ten rows of data into the ListView control.

By default, the ListView ActiveX control may not appear in the list of available ActiveX controls in Access. To make it available, we must add its library file, MSCOMCTL.OCX, from the C:\Windows\System32 folder to the Access references. Once registered, you will see it listed as Microsoft ListView Control, Version 6.0, along with other ActiveX controls.

This library file provides several useful controls, including ListView, TreeView, and ImageList. If you have already followed our earlier TreeView control tutorials, you are familiar with this library.

Adding the Windows Common Controls Library (MSCOMCTL.OCX)

Follow these steps to attach the MSCOMCTL.OCX file to your database:

1. Open your database and press Alt + F11 to launch the VBA editor.

2. From the Tools menu, select References…

3. Click the Browse button.

4. Locate the file MSCOMCTL.OCX (Microsoft Windows Common Controls) in one of the following folders:

   • C:\Windows\System32\ → on 32-bit systems, or on most Windows 11 installations.

   • C:\Windows\SysWOW64\ → on 64-bit systems.

5. Select the file and click Open to attach it to your database.

6. Press Alt + F11 again to return to the database window.

Designing a Sample Form with the ListView Control

We will now design a simple form that matches the sample image shown at the beginning of this tutorial.

1. Create a new blank form in Design View.

2. From the Controls group, select ActiveX Control.

3. In the list of available ActiveX controls, locate and select Microsoft ListView Control, Version 6.0, then click OK to insert it onto the form’s Detail section.

4. Resize the control:

   • Grab the bottom-right resize handle and drag it outward to make the ListView large enough to resemble the sample image.

   • Move the control slightly down and to the right to leave space for a heading label above and some margin on the left.

5. With the ListView still selected, open the Property Sheet and rename the control by setting its Name property to: ListView1

6. Create a Label control above the ListView.

   • Change its Caption property to: ListView Control Tutorial

   • Apply any formatting you prefer (font size, bold, color, etc.) to make the heading stand out.

7. Insert a Command Button below the ListView.

   • Set its Name property to: cmdClose

   • Set its Caption property to: Close

When completed, your form design should look similar to the following layout:

1. Now, save the Form with the name: ListViewTutorial and keep the Form in the design view.

2. Press Alt+F11 to go back to the Form’s Class Module Window.

   The VBA Code.

3. Copy and paste the following Code into the Form's VBA Module, replacing existing lines of code, if any:

   Option Compare Database
   Option Explicit
   
   Dim lvwList As MSComctlLib.ListView
   Dim lvwItem As MSComctlLib.ListItem
   Dim ObjImgList As MSComctlLib.ImageList
   Const prfx As String = "X"
   
   Private Sub cmdClose_Click()
      DoCmd.Close acForm, Me.Name
   End Sub
   
   Private Sub Form_Load()
       Call LoadListView
   End Sub
   
   Private Function LoadListView()
       Dim intCounter As Integer
       Dim strKey As String
   
   'Assign ListView Control on Form to lvwList Object
    Set lvwList = Me.ListView1.Object
    
    'Create Column Headers for ListView
    With lvwList
       .ColumnHeaders.Clear 'initialize header area
      'Parameter List:
   'Syntax: .ColumnHeaders.Add Index, Key, Text, Width, Alignment, Icon
       .ColumnHeaders.Add , , "Name", 2500
       .ColumnHeaders.Add , , "Age", 1200
       .ColumnHeaders.Add , , "Height", 1200
       .ColumnHeaders.Add , , "weight", 1200
       .ColumnHeaders.Add , , "Class", 1200
    End With
    
    'Initialize ListView Control
     While lvwList.ListItems.Count > 0
           lvwList.ListItems.Remove (1)
     Wend
       
    With lvwList
       For intCounter = 1 To 10
           strKey = prfx & CStr(intCounter) '
      'Syntax: .ListItems.Add(Index, Key, Text, Icon, SmallIcon)
           Set lvwItem = .ListItems.Add(, strKey, "Student " & intCounter)
           'Add next columns of data as sub-items of ListItem
           With lvwItem
         'Parameters =      .Add Index,Key,Text,Report Icon,TooltipText
               .ListSubItems.Add , strKey & CStr(intCounter), CStr(5 + intCounter)
               .ListSubItems.Add , strKey & CStr(intCounter + 1), CStr(135 + intCounter)
               .ListSubItems.Add , strKey & CStr(intCounter + 2), CStr(40 + intCounter)
               .ListSubItems.Add , strKey & CStr(intCounter + 3), ("Class:" & intCounter)
   
          End With
       Next
       'reset lvwItem object
       Set lvwItem = Nothing
   End With
   lvwList.Refresh
   
   End Function

4. Save the Form with the name ListView Control Tutorial-01.

   Demo View of the Form.

5. Open the Form in Normal View to have a look at our creation.

   If you find your form with the following image-like display, then you are on the right track.

   

   We need to make some adjustments to the ListView control’s property settings. Earlier, we renamed the control to ListView1 using the standard Access Property Sheet. However, the ListView control has its own dedicated property sheet, which provides more detailed configuration options. Some of these settings also appear in the Access Property Sheet, but many are unique to the control itself.

6. To access it, right-click the ListView control, point to ListViewCtrl Object, and then select Properties from the shortcut menu.

7. This will open the ListView control’s own property sheet, as shown in the image below:

   

8. At the top of the Property Sheet, you will see tabs that group various options. By default, the General tab is active. On this tab, the left side lists option values, while the right side contains corresponding checkboxes.

   For our form, we only need to adjust two ListView properties, which are disabled by default. Once enabled, these allow the ListView to display in different modes—such as large icons, small icons, simple lists, or Report View (as shown in the first image above).

   1. Check the Enabled property on the right side to activate the ListView control.

   2. From the View drop-down list on the left side, select lvwReport.

   3. Click the Apply button to confirm the change.

   4. Click OK to close the Property Sheet.

   Finally, save the form and open it in Normal View. The result should now look like the image shown earlier, except for any differences in form background color or other form-level settings.

The Program's Functional Diagram.

Before diving into the VBA code, it’s important to understand how data items are actually loaded into the ListView control. With a ListBox, the data arrangement is fairly straightforward. However, the ListView control uses a completely different approach. The loading process does not follow the logical sequence we might naturally expect.

Once you see how the data flows from the source into a single row—illustrated as a diagram or flow chart—the concept becomes much easier to grasp. With this visual in mind, understanding the VBA code and its role in the process will be far more intuitive.

The Data Flow Diagram.



1. In the diagram, the box at the top-left corner represents the ListView control.

   The first step in preparing the list is to create the column headings. These headings (shown in red in the diagram) work the same way as field headers in a table’s Datasheet View. Each column heading is added to the ColumnHeaders collection of the ListView control using the ColumnHeaders.Add() method. Since our sample has five columns, the method is called five times, once for each heading.

   The next set of actions loads the actual data. Each row of data represents a single record with five fields. However, these fields are not loaded all at once—they are split between two different object members of the ListView control: ListItems and ListSubItems.

   • The first field value (the value for the first column) is added to the ListItems collection using the ListItems.Add method. For example, in the sample image, the value Student1 (from the first column of the first row) is stored in the ListItems object.

   • From the second column onward, the remaining field values are added as ListSubItems of the corresponding ListItem. This is done using the ListSubItems.Add method, called four times—once each for the Age, Height, Weight, and Class values.

   Together, these two steps complete a single row of data in the ListView control. The diagram illustrates this process with two rows of sample data.

   Once you understand this two-level structure—ListItems for the first column, ListSubItems for the remaining fields—the VBA code that builds the ListView will be much easier to follow.

Let us go to the VBA Code Segment-wise.

In the global declaration section of the module, we have declared the ListView object, the ListItem object, the ImageList object, and a constant variable with the string value "LV".

Dim lvwList As MSComctlLib.ListView
Dim lvwItem As MSComctlLib.ListItem
Dim ObjImgList As MSComctlLib.ImageList
Const prfx As String = "X"




The variable lvwList is declared as a ListView object, lvwItem as a ListItem object of the ListView control, and ObjImgList as an ImageList object. The ImageList object is another ActiveX control that can store image icons for use with both the TreeView and ListView controls. For now, we will set the ImageList aside and return to it later.

The constant Prfx is used as the Key value prefix in the ListItems.Add method, which accepts several optional parameters. The Key value must always be a string type.

The LoadListView() function serves as the main program.

On our form, the ListView control is named ListView1. The first executable statement in the program is:

Set lvwList = Me.ListView1.Object 

Assigns the ListView1 control on the Form into the Object variable lvwList declared in the Global declarations area.

Next, we will get prepared to load the Column Header information.  First, we initialize the ColumnHeader object to ensure that it is empty.  When we repeatedly run the program, the control has a tendency to retain the earlier loaded values in the control.  When you open and close this form more than once, after disabling the 'ColumnHeaders.Clear' statement, you will know the difference. The same set of headings is added to the control every time and will appear in the control with empty rows below.

You can verify this behavior manually with the following steps:

1. Open the demo form once and then close it.

2. Reopen the form in Design View.

3. Right-click the ListView control, highlight the ListViewCtrl Object option, and select Properties from the menu.

4. In the property sheet, go to the Column Headers tab.

5. You will see the first column heading displayed in a text box, with its Index value (1) shown above.

6. Move the mouse pointer to the right side of the index number box. Arrow buttons (left and right) will appear.

7. Click the right arrow to scroll through and display the remaining column labels, one by one, as their index numbers change.

8. If you open and close the form again, you will notice that the Column Headers tab now contains duplicate sets of the same column labels.

The ColumnHeaders.Add method syntax is as follows:

lvwList.ColumnHeaders.Add(Index, Key, Text, Width, Alignment, Icon)

All parameters are optional.

With lvwList
    .ColumnHeaders.Clear 'initialize header area
'Parameter List:
'Syntax: .ColumnHeaders.Add Index, Key, Text, Width, Alignment, Icon
    .ColumnHeaders.Add , , "Name", 2500
    .ColumnHeaders.Add , , "Age", 1200
    .ColumnHeaders.Add , , "Height", 1200
    .ColumnHeaders.Add , , "weight", 1200
    .ColumnHeaders.Add , , "Class", 1200
 End With 

The Index value is automatically assigned as running serial numbers (1, 2, 3, and so on).

The Key value is of the String data type. Although it is not typically used for column headers, it can be assigned if needed.

The Text value is what appears on the control as the column label.

To control the display width of each column, you can assign an approximate width value in pixels, based on the data expected under that column.

If the Text alignment property is omitted, the default is Left alignment (0 - lvwAlignmentLeft). Alternatively, you can set it to Right alignment (1 - lvwAlignmentRight) or Center alignment (2 - lvwAlignmentCenter).

Once the column headings are loaded, the next step is to insert the first record. Specifically, we start by loading the first column value of the first row. But before doing so, we must initialize the ListItems object with the following code segment:

'Initialize ListView Control
  While lvwList.ListItems.Count > 0
        lvwList.ListItems.Remove (1)
  Wend

The next code block loads the record list items one row at a time, generating a total of ten rows with sample values. For demonstration purposes, these values remain mostly constant, with a few variations to highlight the process. This is accomplished by placing the logic inside a For...Next loop, which iterates ten times, thereby creating ten rows of data in the ListView control.

With lvwList
    For intCounter = 1 To 10
        strKey = prfx & CStr(intCounter) '
  'Syntax: .ListItems.Add(Index, Key, Text, Icon, SmallIcon)
        Set lvwItem = .ListItems.Add(, strKey, "Student " & intCounter)
        
  'Add next columns of data as sub-items of ListItem
        With lvwItem
  ' Syntax: .ListSubItems.Add Index,Key,Text,Report Icon,TooltipText
            .ListSubItems.Add , strKey & CStr(intCounter), CStr(5 + intCounter)
            .ListSubItems.Add , strKey & CStr(intCounter + 1), CStr(135 + intCounter)
            .ListSubItems.Add , strKey & CStr(intCounter + 2), CStr(40 + intCounter)
            .ListSubItems.Add , strKey & CStr(intCounter + 3), ("Class:" & intCounter)

       End With
    Next
    'reset lvwItem object
    Set lvwItem = Nothing
End With

The first statement inside the For...Next loop —

strKey = prfx & CStr(intCounter)

— prepares a unique Key value for the first list item (the first column).

All parameters of the ListItems.Add() Methods are optional. However, in this case, the first three—Index, Key, and Text—are used in the same sequence as the Column Headers. The remaining two parameters are reserved for assigning an icon and a small icon image, if needed.

When the value for the first column of a row is assigned to the ListItem (i.e., lvwList.ListItems), that object reference is stored in the lvwItem variable. This allows easy access to its sub-object, ListSubItems, without having to repeatedly write the full object reference.

lvwList.ListItems.Item(index).ListSubItems.Add() 

Expressed in the short form with lvwItem.ListSubItems.Add()

Using the short form 'lvwItem.ListSubItems.Add()' We can load the remaining column values into the ListView control.

The ListSubItems.Add() method accepts its first three parameters in the same order as the ListItem (Index, Key, and Text), followed by the optional Icon image reference and Tooltip Text.

For the Key value of each column, I have appended the current loop counter value plus an offset to ensure uniqueness across all columns. Although the Key parameter can be omitted, it is good practice to use it.

The Method  ListSubItems.Add()  is called four times within the loop to insert values for the second through fifth columns.

These steps repeat nine more times, ultimately creating ten sample records in the ListView control.

The demo database containing this ListView control example is attached, ready to run and explore.

In the next part of this tutorial, we will explore how to search and locate specific values within the ListView control, as well as how to rearrange columns—just like we do in Datasheet View.

DataSavingForm.zip
1. Microsoft TreeView Control Tutorial
2. Creating an Access Menu with a TreeView Control
3. Assigning Images to TreeView Nodes
4. Assigning Images to TreeView Nodes-2
5. TreeView Control Checkmark Add Delete
6. TreeView ImageCombo Drop-down Access
7. Re-arrange TreeView Nodes By Drag and Drop
8. ListView Control with MS-Access TreeView
9. ListView Control Drag Drop Events
10. TreeView Control With Sub-Forms

Read More