We can Import data from external data sources; from another Access database, dBase, Foxpro, Excel and so on. We can Export data from Access into these Applications as well.

Following is a list of topics I have published earlier; either on importing, exporting or working with external data sources from Microsoft Access:

Today, we will explore how to add a range of excel cells data directly into Access Table, by running VBA Code from within Excel?

The Algorithm of the program is as given below:

  1. Create an Access Application Object and open it.
  2. Open the target database within the Access Application.
  3. Keep the Access Application window hidden.
  4. Open the target table from the Database.
  5. Take the count of Rows from one of the Excel data column.
  6. Open a repeating loop to write the excel data one row at a time, from second row onwards.
  7. Repeat the writing action till all the rows are transferred to the Access Table.
  8. Close the table, database and quit MS-Access Application.

The Excel VBA Code is Run by clicking a Command Button on Excel Sheet. Sample image of the Excel Sheet with data and Command Button is given below:

Excel Sheet Data

 

Target Access Table Structure image is given below:

 

Table1 Structure

The Excel VBA Code is given below:

Sub Button1_Click()
    Dim objAcc As Object
    Dim recSet As Object
    Dim DataRow As Long, EndRow As Long
    
    On Error GoTo Button1_Click_Err
    
    'Create Access Application Object
    Set objAcc = CreateObject("Access.Application")
    'Open Database in Microsoft Access window
    objAcc.OpenCurrentDatabase "F:\mdbs\Database4XL.accdb", True
    'Keep Access application window hidden
    objAcc.Visible = False
    
    'Open Access Table to add records from Excel
    Set recSet = objAcc.CurrentDb.OpenRecordset("Table1")
    'Take actual row counts of data for transfer
    EndRow = Sheet1.Range("A" & Rows.Count).End(xlUp).Row

    With recSet
      For DataRow = 2 To EndRow
        .AddNew
        ![Desc] = Sheet1.Range("A" & DataRow).Value
        ![Qrtr1] = Sheet1.Cells.Range("B" & DataRow).Value
        ![Qrtr2] = Sheet1.Cells.Range("C" & DataRow).Value
        ![Qrtr3] = Sheet1.Cells.Range("D" & DataRow).Value
        ![Qrtr4] = Sheet1.Cells.Range("E" & DataRow).Value
        .Update
      Next
    End With
    recSet.Close
    objAcc.Quit
    Set objAcc = Nothing

Button1_Click_Exit:
Exit Sub

Button1_Click_Err:
MsgBox Err & " : " & Err.Description, , "Button1_Click()"
Resume Button1_Click_Exit
    
End Sub

Courtesy: The non-functional raw VBA Code was presented by a User in www.mrexcel.com/forum/microsoft-access, modified by me to make it functional and was originally submitted there.

The first field of the table is an ID field with data type AutoNumber. ID field value is automatically generated when data is inserted into the other fields.