Wave Shaped Reminder Ticker

Wave-Shaped Reminder Ticker.

We have already seen how to create and install a Reminder Ticker that runs in a straight line on the Main Screen. We could do this with a few lines of VBA code and a Label control on the Main Screen. We will try something different this time. This ticker runs in a Zigzag form. An image of a sample run of this method is given below:

Right-click to open the Large Image in a New Tab/Window.

To create this Ticker, we need a series of labels arranged in a wavelike shape, and each one must be named in an easily addressable way using code. A sample design is given below:

Right-click to open Large Image in New Tab/Window.

Automating the Label Creation.

We need to create approximately 42 identical labels. Even after creating them, arranging them in the required zigzag layout would be very challenging. However, this can be done efficiently with VBA Code. The program generates a new form, creates all 42 labels, arranges them in a zigzag pattern, assigns them sequential names, lbl1 through lbl42, and adjusts their other properties as described above.

1. Copy the following Code into a Global Module of your Database and save it.
   

   Public Function ZIGZAG()
   '-----------------------------------------------------------
   'Author  :  a.p.r. pillai
   'Date    :  01/10/2008
   'URL     :  www.msaccesstips.com
   'All Rights Reserved by www.msaccesstips.com
   '-----------------------------------------------------------
   Dim frm As Form, ctrl As Label, t As Long, lngleft As Long
   Dim lngwidth As Long, lngheight As Long, lngtop As Long
   Dim j As Integer, k As Integer, h As Long, G As Long
   
   h = 30: G = 0: t = 0
   lngwidth = 0.1146 * 1440
   lngheight = 0.2083 * 1440
   lngtop = 1 * 1440
   lngleft = 0.16667 * 1440
   Set frm = CreateForm
   For j = 1 To 42
   Set ctrl = CreateControl(frm.Name, acLabel, acDetail, , , lngleft, lngtop, lngwidth, lngheight)
   lngleft = lngleft + lngwidth
   With ctrl
       .Name = "lbl" & j
       .FontName = "Tahoma"
       .FontSize = 8
       .Caption = ""
       .BackStyle = 0
       .ForeColor = 255
    End With
    Next
   G = 0
   For j = 1 To 3
        For k = 1 To 7
           G = G + 1
           Set ctrl = frm.Controls("lbl" & G)
           With ctrl
               .Top = .Top - (h * k)
           End With
           DoEvents
        Next
       t = frm.Controls("lbl" & G).Top
        For k = 1 To 7
            G = G + 1
           Set ctrl = frm.Controls("lbl" & G)
           With ctrl
               .Top = t + (h * 1)
           End With
           t = frm.Controls("lbl" & G).Top
           DoEvents
       Next
   Next
   End Function
   

2. You can run the above Code directly by placing the cursor in the middle of the Code and pressing the F5 Key, or running it from a Command Button's On Click Event Procedure or a Macro.

   Each time the code is executed, it creates a new form with the labels arranged in a zigzag pattern. Once you’ve created it, you can export this form to other projects where you want to install the ZigZag Ticker. Alternatively, you can place the code in a common library database and run it from your new project after attaching the library file to your project.

   Placement of the Ticker Labels.

3. After creating the Labels, click outside the labels and drag over them to select all of them without disturbing the labels' arrangement.

4. Select Copy from the Edit Menu.

5. Open the Main Switch Board (Control Form) in Design View and paste them.

6. When all the labels are still in the selected state, drag and place the Labels into a position where you want the Ticker to appear on the Form.

   We have two more subroutines, run from the Form_Load() and Form_Timer() Event Procedures. In the Form_Load() Event Procedure, format a text message as a string, either by using a constant string or by retrieving text from a Table/Query record field that provides useful information to display to the User as a reminder. Refer to the earlier example, Reminder Ticker Form, which uses data from within the Application as a reminder.

   Formatting Ticker Text.

   The Form_Timer() Event Procedure sequences the Display of Label values, shifting one character at a time across successive labels, an ever-scrolling display of valuable information.

7. Copy and paste the following subroutines into the Form Module where you have pasted the above labels.

   Option Compare Database
   Option Explicit
   Dim txt As Variant
   
   Private Sub Form_Load()
       txt = Space(42) & UCase("Excellence is not a matter of chance. It is a matter of Change. It is not a thing to be waited for. It is a thing to be achieved.")
       Me.Timerinterval=250
   End Sub
   

8. See that the Dim txt As Variant is placed in the Global Area of the Module, which is referenced from the Form_Load() and Form_Timer() Event Procedures.

   Private Sub Form_Timer()
   Dim x As String, k As String, j As Integer, ctrl As Control
   
     x = Left(txt, 1)
     txt = Right(txt, Len(txt) - 1)
     txt = txt & x
     k = Left(txt, 42)
   For j = 1 To Len(k)
       Set ctrl = Me.Controls("lbl" & J)
       Ctrl.Caption = Mid(k, j, 1)
   Next
   End Sub 
   

   Disable the ticker on inactive Form.

9. The following lines of code are useful if you plan to disable the ticker when the Main Form is inactive and run it when the Main Form becomes active again, so that other processes are not interrupted by the Ticker.

Private Sub Form_Deactivate()
   Me.TimerInterval = 0
End Sub

Private Sub Form_Activate()
   Me.TimerInterval = 250
End Sub

Download

Download Demo Database Access2007.zip


Download Demo Database Access2002-03.zip

• Opening dBase Files Directly
• Opening External Data Sources
• PIE Chart Object and VBA
• Column Chart and VBA
• Working with the Chart Object in VBA