LEARN MS-ACCESS TIPS AND TRICKS

Users Group and Permissions

noreply@blogger.com (a.p.r. pillai) — Sun, 07 Mar 2010 16:00:00 +0000

When you create a new Workgroup Information File, as part of the Microsoft Access Security implementation, it is important that the following two steps you follow immediately after creating the new Workgroup Information File (.mdw) file on priority basis:

Create a new Administrator UserID (say myAdmin or whatever name you like) for you and join yourself as a member of the Admins Group Account.

Remove the default Admin User Account from the Admins Group. If this is not done then your database is not secured and anybody can open and use it when MS-Office Software is re-installed.

From now on you must use the new UserID myAdmin to login as Administrator of the Databases that uses this new common Workgroup Information File.

One more thing, the databases that you create after login with the new User Name myAdmin, this User Account will be the Owner of those Databases and other Objects within it.

Remember the Owner of the Database has full authority on all Objects including Administrative Authority (like a member of the Admins Group) to assign permissions to Database Objects and to transfer Ownership of Objects to other Users as well. When the ownership of a particular Object is given to an ordinary User, he has full authority on that object to Run, Modify or Delete that object.

You must implement Object-wise access rights to User Groups before you install your Project for public use. This is done manually from Tools - ->Security - ->User and Group Permissions…

This procedure also has a first priority step, like the above two steps I have mentioned about the Workgroup Information File. That is to remove All Permissions of all Objects for the Users Group Account. Without this step whatever permission settings you assign to the Objects (Forms, Report and so on) will have no effect and Users will have full authority for Design Changes or whatever they want to do with them.

This is done manually and takes some time to go through all groups of Objects to remove all permissions of Users Group Account. Since, this step is required for all new Projects I thought it is better to automate it and here it is for you to try it out. This program is written purely on my own experience with the VBA based procedures and you may use it at your own risk

Copy and paste the following Program into a Standard Module and save it.


Public Function DefaultUsersGrp(ByVal DatabasePathName As String) As Boolean
'----------------------------------------------------------------------------
'Author : a.p.r. pillai
'Date     : March-2010
'Purpose: Remove All Permissions from Users Group Security Account
'All Rights Reserved by www.msaccesstips.com
'----------------------------------------------------------------------------
Dim wsp As Workspace, db As Database, ctr As Container
Dim GroupName As String, doc As Document
Dim L4 As String

Const DB_FULLNO = &H60000
Const OBJS_FULLNO = &H2FE01

'Remove All Permissions on Containers & documents
'for USERS Group

On Error GoTo DefaultUsersGrp_Err

Set wsp = DBEngine.Workspaces(0)
Set db = wsp.OpenDatabase(DatabasePathName)

wsp.Groups.Refresh

GroupName = "Users"

Set ctr = db.Containers("Databases")
Set doc = ctr.Documents("MSysDb")
doc.UserName = GroupName
doc.Permissions = DB_FULLNO

Set ctr = db.Containers("Tables")
GoSub SetPermission

Set ctr = db.Containers("Forms")
GoSub SetPermission

Set ctr = db.Containers("Reports")
GoSub SetPermission

Set ctr = db.Containers("Scripts")
GoSub SetPermission

Set ctr = db.Containers("Modules")
GoSub SetPermission

DefaultUsers_Grp = False

DefaultUsers_Grp_Exit:
   Set db = Nothing
   Set wsp = Nothing
Exit Function

SetPermission:
For Each doc In ctr.Documents
    doc.UserName = GroupName
    If ctr.Name = "Tables" Then
        L4 = Left$(docName, 4)
        If L4 = "MSys" Or L4 = "~sq_" Then
          GoTo nextloopxxx
        End If
    End If
    doc.Permissions = OBJS_FULLNO
nextloopxxx:
Next
Return

DefaultUsersGrp_Err:
MsgBox Err & ": " & Err.Description
DefaultUsersGrp = True
Resume DefaultUsersGrp_Exit
End Function

Remember this Program is run for an external Database that you would like to remove All Permissions of all Objects for the Users Group Account.

Before you run this Program, open the Database that you are targeting and check the current permission settings of all Objects for the Users Group Account. Try the program on a copy of the original Database you are targeting.

Open the Database with the above Code, if you have closed it.

Press Alt+F11 to display the VBA Editing Window and press Ctrl+G to display the Debug Window.

Type the following and press Enter Key:

DefaultUsersGrp "C:\My Documents\myTest.mdb"

Replace the database Pathname in quotes with your own database name.

Command Button

Event Procedure

Open your Test Database and check the current status of the permissions settings of Users Group Account. The check marks from all the permission options you will find disappeared.

Create Security Group Account with VBA

noreply@blogger.com (a.p.r. pillai) — Mon, 01 Mar 2010 12:25:00 +0000

Last week we have learned how to create a Microsoft Access Security User Account(SMITHJOHN) with VBA and learned how to join him as a member of the default Group Account Users. The Users and Admins Group Accounts are already present in the default Workgroup Information File (Sytem.mdw) or in the new Workgroup Information File that you create separately.

If we need to group Users under different categories (like MANAGERS, SUPERVISORS, DATA ENTRY OPERATORS, EDITORS and so on) so that their access rights to different objects can be defined differently at group level and any number of Users can be joined to these groups. Once we clearly define group level access rights all Users joined to that group will inherit the privileges assigned to that Group.

One User can be joined to more than one Group as well. A sample image of the User and Group Accounts control is given below and we will examine how the User SMITHJOHN's Security credentials are appearing in the Control.

In the User Name control SMITHJOHN is selected. The Group Account name Users is appearing under the label Member of indicating that he belongs to that Group Account only. If you look under the Available Group List you can see that the Users Group Account is appearing there also. Unlike the Users Group Account other Group Accounts shown there are created manually for different Group of Users.

If we want to make the User SMITHJOHN as a member of the VEHGRP then all we have to do is to select the VEHGRP under the Available Groups List and click on the Add>> Command Button to copy that name into the Member of: List. Whatever Access Privileges we have assigned to the VEHGRP will be automatically available to the selected User in the User Name control above.

At the end part of last week's main program CreateUser() the following code segment is doing exactly what we did manually in the above paragraph:


.
.
.
   With wsp
     Set tempGrp = .Users(UsrName).CreateGroup("Users")
         .Users(UsrName).Groups.Append tempGrp
         .Users.Refresh
   End With

But, to do that first we must create the Group Account VEHGRP by going through the same procedure like creating a new User Account from the Groups Tab on the Control above. So, the VEHGRP Account was created at some point of time earlier.

Here, we will learn:

How to create a Microsoft Access Security Group Account MANAGER with VBA.

How to join the User SMITHJOHN to the MANAGER Group Account with VBA.

NB: The User and Group Accounts are not case sensitive. Here they are given in Upper Case for legibility only.

The following Program creates the MANAGER Group Account in the Available Groups List:


Public Function CreateUserGrp()
'---------------------------------------------------------------------
'Creating a Security Group Account
'Author : a.p.r. pillai
'Date   : March-2010
'All Rights Reserved by www.msaccesstips.com
'---------------------------------------------------------------------
Dim newGrp As Group, wsp As Workspace
Dim tempGrp As Group
Dim grpName As String, grpID As String

On Error Resume Next

Set wsp = DBEngine.Workspaces(0)

    grpName = "MANAGER"
    grpID = "MGR13579"
  
With wsp
    Set newGrp = .CreateGroup(grpName, grpID)
               .Groups.Append newGrp
               
    If Err = 3390 Then
      MsgBox "Group Name : " & grpName & vbCr & vbCr & "Group PID     : " & grpID & vbCr & vbCr & "Account Name already Exists..! "
      Err.Clear
    End If
    
      .Groups.Refresh
End With

End Function

Copy and Paste the above program into a Standard Module.

Click somewhere in the middle of the Code and press F5 Key to Run the Code and to create the MANAGER Group Account.

You may select Tools - -> Security - -> User and Group Accounts…(from the Database Window).

Select SMITHJOHN in the User Name List.

Check for the name MANAGER in the Available Groups List and you will find it there.

But, the User SMITHJOHN is not yet added to the MANAGER Group Account and this is where we need to add the code-segment, given at the top of this page, to the main program.

The revised VBA Code given below to create the MANAGER Group Account and to add the User SMITHJOHN to this Group Account.


Public Function CreateUserGrp()
'---------------------------------------------------------------------
'Creating a Security Group Account
'Author : a.p.r. pillai
'Date   : March-2010
'All Rights Reserved by www.msaccesstips.com
'---------------------------------------------------------------------
Dim newGrp As Group, wsp As Workspace
Dim tempGrp As Group
Dim grpName As String, grpID As String

On Error Resume Next

Set wsp = DBEngine.Workspaces(0)

    grpName = "MANAGER"
    grpID = "MGR13579"
  
With wsp
    Set newGrp = .CreateGroup(grpName, grpID)
               .Groups.Append newGrp
               
    If Err = 3390 Then
      MsgBox "Group Name : " & grpName & vbCr & vbCr & "Group PID     : " & grpID & vbCr & vbCr & "Account Name already Exists..! "
      Err.Clear
    End If
    
      .Groups.Refresh
End With

'Add the User SMITHJOHN to the MANAGER Group Account
usrName = "SMITHJOHN"

   With wsp
     Set tempGrp = .Users(usrName).CreateGroup(grpName)
         .Users(usrName).Groups.Append tempGrp
         .Users.Refresh
   End With

End Function

If you run the revised Code again it will show an Error Message saying that the MANAGER Group Account already exists, because you have already run this code once. But, the remaining part of the code will run.

If you open the User and Group Accounts control now and select SMITHJOHN in the User Name Control you can see that MANAGER group name is now appearing under the Member of List indicating that the User is a member of the MANAGER Group Account.

See the sample image given below.

MS-Access and Data Processing
Form Bookmarks and Data Editing-3
Form Bookmarks and Data Editing-2
Form Bookmarks and Data Editing
Run Slide-show when Form is idle

Creating User-Account with VBA

noreply@blogger.com (a.p.r. pillai) — Mon, 22 Feb 2010 12:36:00 +0000

For creating a Microsoft Access User-Account manually in the Workgroup Information File (.mdw) we go through Tools - -> Security - -> User and Group Accounts - ->User Name Option. There, we need to provide a unique User Name and a Personal ID to create a User-Account.

We have seen this procedure in the Security Main Menu. The UserIDs, PersonalIDs, Work-GroupIDs and Passwords of Users are maintained in the Workgroup Information File (a database with .mdw extension and the Default Workgroup Information File is System.mdw).

Access privileges to Database Objects are stored within the database itself. Both these two parts of the Combination-Lock (UserID with PersonalID in Workgroup Information File and access rights to individual objects for each User/Group maintained within database) works together. Individual User gets access to Objects with the right UserID, Password and PersonalID. PersonalId is a very important element of the User-Profile and we need it again, if we ever need to recreate a Workgroup Information File, when the existing one is corrupted or lost.

UserIDs and GroupIDs can be created and managed only by Administrators (a member of the Admins Group with Administrator privileges) of the Database.

First, let us create a test User Account manually. Go through the following procedure for creating a User Account manually and see how it is done?

User Name: JOHNSMITH (maximum 20 characters)

Personal ID: JS123456 (4 to 20 Alphanumeric characters)

Visit the Page: Create MS-Access User-Account for more details.

Select Tools - -> Security - -> User and Group Accounts

Click New… in the Users Tab.

Type JOHNSMITH in the Name control.

Type JS123456 in the Personal ID control.

Click OK to complete the procedure.

By default all Users will be members of the Users Group. If the User is going to be part of any other User-Groups then that Group Name must be selected from the Available Groups List and Add it to the Member of list at the right hand side.

Let us see how to create a User-Account with VBA, except the procedure explained for joining the User to a particular Group. We will examine the procedure for joining the User to a Group later, after learning to create a Group Account with VBA.

The following VBA Code creates a User Account with the User Name: SMITHJOHN, with the Personal ID: SJ78901 and with an initial Password: SMITHJOHN:



Public Function CreateUsers()
'---------------------------------------------------------------------------------
'Author : a.p.r. pillai
'Date   : Feb-2010
'All Rights Reserved by www.msaccesstips.com
'Other Ref: http://www.msaccesstips.com/2006/11/create-msaccess-user-account.shtml
'---------------------------------------------------------------------------------
Dim wsp As Workspace
Dim newUser As User, tempGrp As Group
Dim UsrName As String, PersonalID As String
Dim Password As String

On Error Resume Next

Set wsp = DBEngine.Workspaces(0)

    UsrName = "SMITHJOHN" ' 1 to 20 characters.
    PersonalID = "SJ78901" 'upto 4 to 20 alphaumeric characters
    Password = "SMITHJOHN" 'upto 14 characters except NULL
    
'Create User Account with personalID
   Set newUser = wsp.CreateUser(UsrName, PersonalID, Password)
   wsp.Users.Append newUser
   
   If Err = 3390 Then
      MsgBox "User Name : " & UsrName & vbCr & vbCr & "User PID    : " & PersonalID & vbCr & vbCr & "Account Name already Exists..! "
      Err.Clear
      Exit Function
   End If
   wsp.Users.Refresh
   
'Users Group must be created and joined the
'User to it. When created manually this step
'(for Users Group)is done automatically.
   With wsp
     Set tempGrp = .Users(UsrName).CreateGroup("Users")
         .Users(UsrName).Groups.Append tempGrp
         .Users.Refresh
   End With

End Function

When we create a User-ID manually we can only set a password for the User after opening a new MS-Access Application window and by going through the Menu Tools- ->Security- ->User and Group Accounts- - > and log-in without a password and select Change Logon Password Tab of the Dialog Control and set a new Password.

Copy and Paste the above Code into a Standard Module and save it.

Click somewhere in the middle of the Code and press F5 to Run the Code and create the User Account in the active Workgroup Information File.

Select Tools - ->Security- ->User and Group Accounts and check for the User Name SMITHJOHN in the list.

The User-Names are in alphabetical order.

We can check for the presence of a particular User Name in the active Workgroup Information File with the following VBA Code:


Public Function Check4UserAccount(ByVal strUsrName As String) As Boolean
'------------------------------------------------------------------------
'Author : a.p.r. pillai
'Date   : Feb-2010
'All Rights Reserved by www.msaccesstips.com
'------------------------------------------------------------------------

Dim WS As Workspace, msg As String
Dim UsrName As String, K As User, Flag As Boolean

Set WS = DBEngine.Workspaces(0)

'All the Users belong to the Common Group 'Users'
Flag = False
With WS.Groups("Users")
        For Each K In .Users
                  If K.Name = strUsrName Then
                          Flag = True
                          Exit For
                  End If
        Next
End With

If flag Then
     MsgBox "User Name: " & strUsrName & " Already Exists! "
End If

Check4UserAccount = flag

End Function

Type the following in the Debug Window (Immediate Window) and press Enter Key to run the above Code:

Check4UserAccount "SMITHJOHN"

If you have not run the first program to create the User Account SMITHJON then to test the second Program, Call the above function with the Admin User Name.

Type the following in the Debug Window (Immediate Window) and press Enter Key:

Check4UserAccount "Admin"

Form Bookmarks and Data Editing-3
Form Bookmarks and Data Editing-2
Form Bookmarks and Data Editing
Run Slide-show when Form is idle
Filter Function Output in ListBox-2

Microsoft Date Time Picker Control

noreply@blogger.com (a.p.r. pillai) — Sun, 14 Feb 2010 05:29:00 +0000

We have learned how to use Calendar Control for easy entry of Date Values into Fields on Form through the earlier Article: Animated Floating Calendar. We have used a single Calendar Control for several Date Fields by moving the Calendar Control automatically near the selected Date Field with unfolding animation.

We have used this method to save space on the Form otherwise we need to place several Calendar Controls linked to each date field on the Form.

Now we have a better ActiveX Control – Microsoft Date Time Picker – a Calendar Control that almost looks like a Combo Box on Form and easy to use.

Let us get into a simple example to learn how to use this Calendar for a Date Field on a Form.

Import the following Objects from C:\Program Files\Microsoft Office\Office11\Samples\Northwind.mdb sample database:

Table: Employees

Form: Employees

Open the Employees Form in Design View.

Select the Company Info Tab.

Select ActiveX Control… from Insert Menu.

Select Microsoft Date and Timer Picker Control from the displayed list and click OK to create a control on the Form.

Move the control near the HireDate Field and resize it as shown on the sample design of the Form given below:

We can set the Control Source Property of Date Time Picker to HireDate and remove the existing HireDate Field.
The HireDate field cannot be blank. When you make a record current with HireDate Field blank or attempt to add a new record the Date Time Picker will show an Error Message: Can't set value to NULL when CheckBox Property=FALSE.

CheckBox Property

Yes

So, first thing first, ensure that the Date Time Picker Control you have added to the Form is in selected state or click to select it, display the Property Sheet (View - -> Properties or Alt+Enter) of the Calendar Control and change the Control Source Property Value to HireDate and change the CheckBox Property Value to Yes.

When you move to a particular record the Calendar will automatically move to the date earlier recorded in the HireDate Field. If you want to change the existing HireDate then move the Calendar to the desired Year and Month and click on the required date.

When you move to a record with HireDate Field value NULL the Check-Mark disappears and the HireDate field looks like disabled indicating that it is empty but the field shows the date value of last record accessed. If you click on the drop down control of the Calendar to open it then the date value, shown from last accessed record will be entered into the HireDate field immediately, whether you want it or not. You can remove the CheckMark to empty the field or select correct date from the Calendar to overwrite the wrong value.

If you prefer to set Date by incrementing or decrementing individual segment (day/month/year) of the Date value, like you do on a Digital Clock, then you may change the UpDown Property Value to Yes. This will change the Drop-down control of the Calendar to a Spin Button Control and the normal Calendar View will not be available.

You may click on the Day Segment of the Date value and use the Spin Button Control of the Date Time Picker to increase or decrease the value to the desired level. Use the same method for Month and Year Values.

You may experiment with the Date Time Picker Control, keeping those points I have mentioned above, to understand the behavior of the Calendar control better.

If you want to enter Time rather than Date into a field from the Date Time Picker then change the Format Property Value to 2. This will automatically change the UpDown Control to Yes and the Spin Button control appear in place of the drop-down control and these can be used to set each segment (hh:mm:ss AM/PM) of the Time Value individually as explained above for date.

Form Bookmarks and Data Editing-2
Form Bookmarks and Data Editing
Run Slide-show when Form is idle
Filter Function Output in ListBox-2
Filter Function Output in ListBox

Form and Report Open Arguments

noreply@blogger.com (a.p.r. pillai) — Fri, 05 Feb 2010 07:25:00 +0000

While opening a Report or Form we can pass several Optional Values as Run-Time Arguments to control the output on the Report or to change the Form Open Mode depending on the User's Profile.

For example: If the Current User belongs to a particular Users Group, in the Security Workgroups, who has only enough privilege to view the data and not to Add or Edit then we can open the Form in Read-only mode otherwise in Normal Mode, when the Current User attempts to open the Form.

The following Code checks whether the Current User belongs to a particular User Group. The following Code of CheckGroup() Function must be copied into a Standard Module in your Database.


Public Function CheckGroup(ByVal strUsr As String, grpName As String) As String
'-----------------------------------------------------
'Author : a.p.r. pillai
'Date   : Feb-2010
'URL    : www.msaccesstips.com
'Remarks: All Rights Reserved by www.msaccesstips.com
'-----------------------------------------------------
Dim wsp As Workspace
Dim GrpArray() As Variant, grpcnt As Integer
Dim GrpOut As Variant, j As Integer

Set wsp = DBEngine.Workspaces(0)

grpcnt = wsp.Users(strUsr).Groups.Count - 1
ReDim GrpArray(0 To grpcnt) As Variant

'User may belong to more than one User Group
'Create an Array of Group Names
For j = 0 To grpcnt
    GrpArray(j) = wsp.Users(strUsr).Groups(j).Name
Next

'Compare Admins with the Array List
'if matches then 'Admins' will be output in grpout Array
GrpOut = Filter(GrpArray(), grpName, True)

CheckGroup = GrpOut(0)

End Function

The CheckGroup() Function must be called from a Command Button Click Event Procedure (we will do this at the end of this Article) as shown below to check and returns the User Group Name to open the Form in a particular Mode.


Private Sub cmdOpenForm_Click()
Dim strGrp

strGrp = CheckGroup(CurrentUser, "Admins")

If strGrp = "Admins" Then
    DoCmd.OpenForm "Products", acNormal, , , acFormReadOnly
Else
    DoCmd.OpenForm "Products", acNormal
End If

End Sub

The CheckGroup() program creates an Array of Work Groups of the User and checks whether the User belongs to Admins Group and returns the result. If the result value is Admins then the Products Form is open in Read-Only Mode otherwise in Normal Mode.

The Workgroups Array creation is necessary because a particular User can belong to one or more Workgroups, like Admins, Users (default), Supervisor, Manager, Editor or any other group in the Workgroup Information File(database.mdw), which he/she has been joined to.

The Filter() Function compares the text "Admins" in the array elements and if found it is output into the GrpOut(0) element.

We cannot use the Filter() Function in Form Module Sub-Rotuine, because it will clash with the Form Property name Filter.

Coming back to the Open Arguments of Form and Reports we can pass the name of a Query as Filter Argument or a WHERE condition without the word WHERE. But, there is another parameter known as Open Argument (OpenArgs) through which you can pass a value to the Report or Form and read it back in the Class Module of Report or Form from the same variable OpenArgs and use it for whatever purpose you passed it.

We try a simple example to learn the usage of this parameter. We need few objects from the C:\Program Files\Microsoft Office\Office11\Samples\Northwind.mdb sample database.

Import the following from the Northwind.mdb sample database:

Table: Products

Table: Categories

Query: Products by Category

Report: Products by Category

Open a new Form and create a Combo Box with the Category Name alone from the Categories Table.

Select the Combo Box and display its Property Sheet (View - -> Properties or press Alt+Enter).

Change the Name Property value to cboCategory.

Create a Command Button and change its Name Property value to cmdOpen and the Caption Property Value to Open Report.

Select EventProcedure in the On Click Event Property and click on the build (…) button to open the Class Module of the Form with the empty Sub-Routine lines.

Copy and paste the following VBA Code overwriting the existing line or copy and paste the middle line alone:


Private Sub cmdOPen_Click()
   DoCmd.OpenReport "Products by Category", acViewPreview, , , , Nz(Me!cboCategory, "")
End Sub

Save the Form with the name Open Argument Demo or any other name you prefer.

Open Products by Category Report in Design View.

Display the Class Module (View - -> Code)

Copy and Paste the following Code into the Class Module:


Private Sub Report_Open(Cancel As Integer)
Dim strFilter As String

If IsNull([OpenArgs]) Then
   Exit Sub
End If

Report.Title.Caption = Report.Title.Caption & " (" & [OpenArgs] & ")"

strFilter = "CategoryName = '" & [OpenArgs] & "'"
Report.Filter = strFilter
Report.FilterOn = True


End Sub

Save the Report with the Code.

Open the Open Argument Demo Form in Normal View.

Select a Product Category Name (say Beverages) in the Combo Box.

Click on the Open Report Command Button.

Products by Category

Beverages

Make the Combo box value empty by deleting the current value and click on the Open Report Command Button.

This time all the Products by Category will appear on the Report and the heading will remain without any change. We are testing the presence of some values in the OpenArgs Variable in the Report Open Event Procedure, if it is Null then terminate the Sub-Routine.

Do the following to try the first two Programs given on the top of this page:

Open the Open Argument Demo Form in Design View.

Create a second Command Button on the Form.

Display the Property Sheet of the Command Button (View - -> Properties).

Change the Name Property value to cmdOpenForm and change the Caption Property Value as Open Form.

Display the Class Module (View - -> Code).

Copy and paste the second Program from the top into the Module and save the Open Argument Demo Form.

Create a Tabular type Form for Products Table and name the Form as Products.

Open the Open Argument Demo Form and click on the Open Form Command Button.

If you have not implemented Microsoft Access Security, you are by default the Admin User, a member of the Admins Group, and the Products Form will open in Read-Only mode.

Form Bookmarks and Data Editing
Run Slide-show when Form is idle
Filter Function Output in ListBox-2
Filter Function Output in ListBox
Dynamic List Box Contents

Indexing and Sorting with VBA

noreply@blogger.com (a.p.r. pillai) — Thu, 28 Jan 2010 13:47:00 +0000

A Table is normally created with a Primary Key or Index to arrange the records into certain order to view or process. Primary Key or Index can have one or more fields, in order to make the Key Values Unique, if this is not possible with a single field.

If you open the Employees Table from C:\Program Files\Microsoft Office\Office11\Samples\Northwind.mdb sample Database in design view you can see that the EmployeeID Field is defined as Primary Key.

To create an Index manually and to define it as Primary Key:

Open the Table in design View.

Click at the left side of the Field Name to select it.

Click on the Indexes Toolbar Button.

You may give any suitable name in the Index Name Field replacing PrimaryKey, if you would like to do so.

If the Record Values in the selected field are not unique then you can select more data fields (up to a maximum of ten Fields) to form Unique Key for the Primary Key.

You may click and drag over the Fields to select them (if they are adjoining fields) or click on each field by holding the Ctrl Key to select fields randomly.

The above procedure is for creating a PrimaryKey Index for the Table. We can create more than one Index for a Table. But, only one Index can be active at one time.

We can activate an existing Index of a Table or create new Index through VBA and use it for data processing. We will learn here how to create a new Index with the name myIndex for a Table through VBA, activate it and use it for data processing and delete it at the end of the process.

We must validate the presence of myIndex in the Indexes collection of the Table, if found then activate it, otherwise create myIndex and activate it for data processing.

We will use Orders and Order details Table from Northwind.mdb sample database. We will organize the Order Details Table in Order Number sequence so that Order-wise Total Value of all items can be calculated and updated on the same Order record in Orders Table.

Following are the data processing steps which we follow in the VBA Routine to update the Orders Table with order-wise Total Value from Order details Table:

Open Orders Table for Update Mode.

Open Orders Details Table for Input.

Check for the presence of myIndex in the Order Details Table, if found then activate it, otherwise create myIndex and activate it as current Index.

Initialize Total to Zero.

Read the first record from the Order details Table.

Calculate Total Value of the item using the Expression: Quantity * ((1-Discount%)*UnitPrice).

Add the Value to the Total.

Read the next record and compare with the earlier Order Number, if same then repeat step-6 and 7 until the Order Number changes or no more records to process from Order Details Table.

Find the record with the Order Number in Orders Table.

If found then edit and updateTotal into the TotalValue Field in Orders Table.

Check for End Of File (EOF) condition of Order Details Table.

If False then repeat the Process from Step-4 onwards, otherwise Close files and stop Run.

To try the above method Import Orders and Order Details Tables from C:\Program Files\Microsoft Office\Office11\Samples\Northwind.mdb (Access 2003) or C:\Users\User\My documents\Northwind 2007.accdb (Access 2007, if not available then you must create from Local Templates)

Open Orders Table in Design View.

Add a new Field with the name TotalValue with Numeric (Double) data Type in Orders Table.

Order ID

Save the Orders Table.

Open the VBA Editing Window (Alt+F11).

Create a new Standard Module from Insert Menu.

Copy and Paste the following VBA Routine and save the Module.


Public Function CreateIndex()
Dim db As Database, fld As Field, tbldef As TableDef
Dim idx As Index, rst As Recordset, PreviousOrderID As Long
Dim CurrentOrderID As Long
Dim xQuantity As Long, xUnitPrice As Double
Dim xDiscount As Double, Total As Double, rst2 As Recordset

On Error Resume Next

Set db = CurrentDb
Set rst = db.OpenRecordset("Order Details", dbOpenTable)
'Check for presence of myIndex, if found set as current
rst.Index = "myIndex"
If Err = 3800 Then
'myIndex not found
    Err.Clear
    GoSub myNewIndex
End If

On Error GoTo CreateIndex_Err

Set rst2 = db.OpenRecordset("Orders", dbOpenTable)
rst2.Index = "PrimaryKey"
PreviousOrderID = rst![Order ID]
CurrentOrderID = PreviousOrderID
Do Until rst.EOF
    Total = 0
    Do While CurrentOrderID = PreviousOrderID
        xQuantity = rst![quantity]
        xUnitPrice = rst![unit price]
        xDiscount = rst![discount]
        
        Total = Total + (xQuantity * ((1 - xDiscount) * xUnitPrice))
        rst.MoveNext
        PreviousOrderID = CurrentOrderID
        If Not rst.EOF Then
            CurrentOrderID = rst![Order ID]
        Else
            Exit Do
        End If
    Loop
    rst2.Seek "=", PreviousOrderID
    If Not rst2.NoMatch Then
        rst2.Edit
        rst2![totalvalue] = Total
        rst2.Update
    End If
    PreviousOrderID = CurrentOrderID
Loop

rst.Close
rst2.Close

'Delete temporary Index
Set tbldef = db.TableDefs("Order details")
tbldef.Indexes.Delete "myIndex"

CreateIndex_Exit:
Exit Function

myNewIndex:
rst.Close
Set tbldef = db.TableDefs("Order Details")
Set idx = tbldef.CreateIndex("myIndex")

Set fld = tbldef.CreateField("Order ID", dbLong)
idx.Fields.Append fld
Set fld = tbldef.CreateField("Product ID", dbLong)
idx.Fields.Append fld
tbldef.Indexes.Append idx
tbldef.Indexes.Refresh
Set rst = db.OpenRecordset("Order Details", dbOpenTable)
rst.Index = "myIndex"
Return


CreateIndex_Err:
MsgBox Err.Description, , "CreateIndex()"
Resume CreateIndex_Exit

End Function

Click somewhere in the middle of the VBA Routine and press F5 or click Run Command Button to execute the Code and update the Orders Table.

At the beginning part of the Code we are attempting to make one of the Indexes (myIndex) of Order Details Table active. Since, myIndex is not yet created on the Table this action runs into an Error condition. we are trapping this Error Code and passes control to the Sub-Routine to create myIndex and to add it to the Indexes collection. The new Index is activated in preparation for data processing.

Next steps calculate Order-wise Total Values and updates on Orders Table.

At the end of the process myIndex is deleted from the Indexes Collection of Order Details Table.

Data Upload Controls

noreply@blogger.com (a.p.r. pillai) — Tue, 12 Jan 2010 15:47:00 +0000

In some Projects we have to upload data regularly from external data sources like dBase, Excel, flat files like CSV, Text and so on. The external file can remain linked to the Project and the data from them can be added into the local MS-Access Table for preparing Reports

For example, let us say we have an MS-Access Application that prepares monthly Reports on Profitability of Businesses and to do this we must upload raw data on Revenue and Expenses received every month in one of the file Formats mentioned above. If our Application is designed in a such way that when the existing linked file is replaced with new data file with the same name then the Application must be able to identify the presence of new data in the attached file and allow the User to upload the new records into the master file. But, before this action is allowed it become our responsibility as a developer to see that the data once uploaded is not allowed into the System again.

To do this we must install a procedure that will check for the presence of new data in the attached File. If found then enable a Command Button that will allow the User to click and upload the new data into the System. Otherwise keep the Command Button disabled till such time fresh data is detected in the attached file.

So, how do we detect the presence of fresh data in the attached file? Depending on the type of file we can use different approaches to determine the presence of fresh data in the attached file by checking continuity of some Control Number like Invoice Number or the Last Receipt Date, or any other set of unique values that you can depend on from the last uploaded data, and compare them with those Values of the attached file. If the compared values on both files are same then we can assume that the attached file contents are already uploaded earlier, otherwise prepare to upload fresh data. For this kind of checking we may prepare few Queries to filter the set of values from both files and read those values into a VBA routine to compare and control the flow of action.

But, I use a simple method to check the presence of new data in the attached file. Before going into that we have to consider few other issues. If the attached external file is on the local drive of each User and all of them are allowed to run the upload action then it is difficult to keep control of this action and the data can go wrong as well. If the attached file is kept on Server and only one authorized User is allowed to execute the Upload action then there can be some control over the procedure. Depending on all these considerations we have to device a method to upload the data correctly into the database.

I have several Applications that upload data from AS400, dbase, Excel and AS400 Report Spool Files too. I have tried out several methods to detect the presence of fresh information in those files using Queries with control data from tables within the Database and from linked tables. Perhaps, you may wonder what I did for AS400 Report Spool Files. This File cannot be kept attached with the database because it doesn’t have the correct data table format except the Detail Lines.

I have developed programs that will read the spool file line by line and discard unwanted lines like Header, Footer, underlines, blank lines etc. and to take only data lines cut into text fields in a Table initially before converting each field values into their respective data types and write it out into a new table.

But, the question remains as how do I keep track of the presence of new Report Spool File that cannot be kept attached to the Database at all. It is a simple trick. At the end of the upload action of the current file I will make a copy of first 50 lines of the Spool File and create a second control file. Whenever the Application is open by the User a program is run to open both files and do a line by line comparison. If there is no difference in the first 50 lines of both files then the data was already uploaded into the System otherwise the System is prepared to upload fresh data from new file.

After trying several methods with different file types I thought we need a simple method that should work for all kind of files (attached to the system or not) and created one, which is presented below for your use, if needed.

We need a small table with the following Fields:

Field Name	Data Type	Field Size
FileLength	Long Integer
FileDateTime	Date/Time
UserName	Text	25
UploadDate	Date/Time
FilePath	Text	255

The sample table in Datasheet View:

The idea works something like this. When we upload the file contents we will save some basic information of the attached file, like File-Size in number of bytes and the last modified date and time of the file. Besides that, the name of the User (if the database is implemented with Microsoft Access Security) who is authorized to run the upload action and the date of last upload event took place.

We can read the attached File-Size in bytes with the Function: FileLen(PathName) and the File's last modified Date and Time can be obtained with the Function FileDateTime(PathName). After the upload action these values can be updated into the above table to cross-check with the values of the external file to determine the presence of new data. If needed we can set the attached file's Read-Only attribute ON with the Function SetAttr(PathName,vbReadOnly) so that the file can be protected from inadvertent changes. It can be reset to Normal with SetAttr(PathName,vbNormal).

A program must be run immediately after the Main Switchboard Form is open and cross check the File-size and the File Date/Time recorded in the table with the attached file's attributes and if found different then we can be sure that new data have arrived and enable the Command Button so that the User can click and upload new data.

But, if the User kept the Application open and replaced the attached file with new one then the Button will remain disabled because the status checking program runs only when the Main Switchboard opens. Instead of asking the user to close and open the Application again, as a standard procedure in these circumstances, we can create another Command Button with Refresh Caption so that when the User clicks on this Button we can run the above procedure and enable the Upload Button if the file attributes indicates the presence of new file.

A sample VBA Routine is given below that reads the information from the table and cross checks with the attributes of the attached file and Enable/Disable the Upload Command Button.

 
Public Function UploadControl(ByVal frmName As String)
'------------------------------------------------------
'Author   : a.p.r. pillai
'Date     : January-2010
'Remarks  : Data Upload control Routine
'         : All Rights Reserved by www.msaccesstips.com
'------------------------------------------------------
Dim frm As Form, lnglastFileSize, dtlastModified, txtFilePath
Dim lngExternalFileSize, dtExternalModified, authUser
Dim tblControl As String, cmdCtrl As CommandButton

tblControl = "UploadCtrl"
authUser = "LizzaMinnelli"
Set frm = Forms(frmName)
Set cmdCtrl = frm.Controls("cmdUpload")

'Read last recorded information from the Control Table
lnglastFileSize = DLookup("FileLen", tblControl)
dtlastModified = DLookup("FileDateTime", tblControl)
txtFilePath = DLookup("FilePath", tblControl)

'Get the External File information
lngExternalFileSize = FileLen(txtFilePath)
dtExternalModified = FileDateTime(txtFilePath)

If (lngExternalFileSize <> lnglastFileSize) And (dtlastModified <> dtExternalModified) Then
    If CurrentUser = authUser Then
        cmdCtrl.Enabled = True
    Else
        cmdCtrl.Enabled = False
    End If
End If

End Function

The Main SwitchBoard, that has a Command Button with the name cmdUpload, should call the above Program through the Form_Current() Event Procedure of the Form passing the Form Name as Parameter like the following example:


Private Sub Form_Current()
    UploadControl Me.Name
End Sub

If Uploading authority is assigned to a particular User then the Current User's UserID (retrieved with the function CurrentUser) also can be checked with the UserName Field Value before enabling the Command Button cmdUpload..

Run Slide-show when Form is idle
Filter Function Output in ListBox-2
Filter Function Output in ListBox
Dynamic List Box Contents
Office Assistant and MsgBox Menus-3

Auto Numbering In Query Column

noreply@blogger.com (a.p.r. pillai) — Mon, 04 Jan 2010 16:37:00 +0000

We know how to create an Auto-number Field in a Table to generate Unique Sequence numbers automatically for the records added to the Table. We know how to create Sequence Numbers for data lines on Reports.

On Reports, create a Text Box in Detail Section of the Report, write the expression =1 in the Control Source Property and change the Running Sum Property Value to Over All or Over Group. If you need sequence numbers for each Group separately, depending on the Sorting and Grouping settings on the Report, then the Over Group option must be set in the Property otherwise Over All for continuous numbers from start of the Report to the End.

If you want to create Running Sum value of a Field, like Quantity or Total Price, then set the Running Sum Property value as explained above. For more details on Running Sum as well as creating Page-wise Totals on Access Reports visit the Page with the Title: MS-Access Report and Page Totals.

But, Auto-numbering in Queries looks somewhat strange to ask for unless you want to use the Query result for display purposes or the output created from that should have sequence numbers for some reason. Any way this requirement was raised by a participant in a MS-Access Forum on the Net and nobody (including me) could give a clear cut solution except some alternatives. I chipped in with a solution of my own, even though I was not happy with that either.

The Access User who has raised the question in the Forum made direct contact by sending an E-mail to me asking for a solution.

This made me thinking again on that topic and did few trial runs of few simple methods. Finally I could come up with a Function that can do the trick and I am presenting it here so that you can also use it, if you really need it.

It is important to know the usage of the QrySeq() Function in Queries in a new Column to create Sequence Numbers. The Function must be called with few Parameter Values using the values from the Query itself. So, before presenting the VBA Code of the Function I will give some details of the Parameters.

Usage of the Function in the Query Column is as shown below:

SRLNO: QrySeq([ORDERID],"[ORDERID]","QUERY4")

The QrySeq() Function need three Parameters.

The First Parameter must be Unique Values available from any Field in the Query.

Second Parameter is the Column Name of the first parameter in Quotes.

Third Parameter is the Name of the Query from where you call the Function.

The Query, from where the QrySeq() Function is called should have a column of Unique Values, like Autonumber or Primary Key Field. If this is not readily available then create a Column by joining two or more existing fields (like NewColumn:([OrderlD] & [ShippName] & [RequiredDate] & [Quantity] from the existing column values and ensure that this will form Unique values in all records and pass this Column value ([NewColumn]) as first Parameter.

The first Parameter Column Name must be passed to the Function in Quotes ("[NewColumn]") as second parameter.

The Name of the Query must be passed as third parameter.

NB: Ensure that you save the Query first, after every change to the design of the Query, before opening it in Normal View, with the Function in place, to create the Sequence Numbers correctly.

Now, the simple Rules are in place it is time to try out the Function.

Copy and Paste the following VBA Code into a Standard Module in your Database:


Option Compare Database
Option Explicit

Dim varArray() As Variant, i As Long

Public Function QrySeq(ByVal fldvalue, ByVal fldName As String, ByVal QryName As String) As Long
'-------------------------------------------------------------------
'Purpose: Create Sequence Numbers in Query in a new Column
'Author : a.p.r. pillai
'Date : Dec. 2009
'All Rights Reserved by www.msaccesstips.com
'-------------------------------------------------------------------
'Parameter values
'-------------------------------------------------------------------
'1 : Column Value - must be unique Values from the Query
'2 : Column Name  - the Field Name from Unique Value Taken
'3 : Query Name   - Name of the Query this Function is Called from
'-------------------------------------------------------------------
'Limitations - Function must be called with a Unique Field Value
'            - as First Parameter
'            - Need to Save the Query after change before opening
'            - in normal View.
'-------------------------------------------------------------------
Dim k As Long
On Error GoTo QrySeq_Err
restart:
If i = 0 Or DCount("*", QryName) <> i Then
Dim j As Long, db As Database, rst As Recordset
    i = DCount("*", QryName)
ReDim varArray(1 To i, 1 To 3) As Variant
Set db = CurrentDb
Set rst = db.OpenRecordset(QryName, dbOpenDynaset)
For j = 1 To i
    varArray(j, 1) = rst.Fields(fldName).Value
    varArray(j, 2) = j
    varArray(j, 3) = fldName
    rst.MoveNext
Next
rst.Close
End If

If varArray(1, 3) & varArray(1, 1) <> (fldName & DLookup(fldName, QryName)) Then
    i = 0
    GoTo restart
End If

For k = 1 To i
If varArray(k, 1) = fldvalue Then
    QrySeq = varArray(k, 2)
    Exit Function
End If
Next

QrySeq_Exit:
Exit Function

QrySeq_Err:
MsgBox Err & " : " & Err.Description, , "QrySeqQ"
Resume QrySeq_Exit

End Function

Import the Orders Table from C:\Program Files\Microsoft Office\Office11\Samples\Northwind.mdb sample database.

Copy and Paste the following SQL String into the SQL Editing View of a New Query and save the Query with the Name: AutoNumberQuery:


SELECT Orders.*, QrySeq([OrderID],"OrderID","AutoNumberQuery") AS SRLNO
FROM Orders;

Select Save from File Menu or click on the Save Toolbar Button.

Open the Query in normal view.

Check the SRLNO Column for Sequence Numbers.

Here, the OrderID in the Orders Table have unique field values and we could easily get away with the Sequence Numbers correctly in SRLNO Column.

Let us pretend for a moment that we don't have a single field with Unique Values in the Query. We must create a Column with Unique Values by joining two or more Columns available in the Query and pass it to the QrySeq() Function.

Let us try such an example with the Orders Table.

Copy and Paste the following SQL String into a new Query and Save the Query with the name AutoNumberQuery2.


SELECT Orders.*, [ShipName] & [RequiredDate] AS NewColumn, 
QrySeq([NewColumn],"NewColumn","AutoNumberQuery2") AS SRLNO
FROM Orders;

Open the Query in normal View to check whether the Serial Numbers were created correctly or not.

When there are several records it is difficult to check whether the Column Values we have passed to the Function are really unique and the Serial Numbers generated have no duplicates in them by manually checking through the records. Instead, we will take a Count of Serial Numbers appearing more than once in the Records, if any, with the use of a Total Query using AutoNumberQuery2 as Source.

Create a new Query using the following SQL String and name the new Query as DuplicatesCheckQ:


SELECT AutoNumberQuery2.SRLNO, Count(AutoNumberQuery2.SRLNO) AS CountOfSRLNO
FROM AutoNumberQuery2
GROUP BY AutoNumberQuery2.SRLNO
HAVING (((Count(AutoNumberQuery2.SRLNO))>1));

Open DuplicatesCheckQ Query in Normal View.

You will find the following result showing SRLNO Column having the same number appearing more than once in the records indicating that the Unique Column Values we have created for the Function are not really Unique and have duplicates in them.

This can be rectified only by adding more Column Values to the NewColumn expression to eliminate the chance of ending up with duplicates.

This method is only an alternative in the absence of an AutoNumber or Primary Key field Values and not with 100% percent success rate because when you add more records to the Source Table it is likely that it can fail again. In this case the only solution is to join more fields to the expression in NewColumn so that we can reduce the chance of failures.

Now, to correct the above Query add the [Freight] Value Column also to the NewColumn expression. Or Copy and paste the following SQL String into the AutoNumberQuery2 Query overwriting the earlier SQL string in there and save the Query.



SELECT Orders.*, [ShipName] & [RequiredDate] & [Freight] AS NewColumn, 
QrySeq([NewColumn],"NewColumn";,"AutoNumberQuery2") AS SRLNO
FROM Orders;

Open the DuplicatesCheckQ Query again to check for duplicates. If the result is empty then the Sequence Numbers generated will be correct.

If you have a different solution to this problem, then share it with me too. I don't need a refined version of the above Code or method but a different approach to arrive at the same or better result.

Filter Function Output in ListBox-2
Filter Function Output in ListBox
Dynamic List Box Contents
Office Assistant and MsgBox Menus-3
Office Assistant and MsgBox Menus-2

Web Browsing within Access Form

noreply@blogger.com (a.p.r. pillai) — Mon, 28 Dec 2009 02:42:00 +0000

Browsing the World Wide Web is nothing new to us. But, how about organizing the Web Addresses of frequently visiting Websites in a Table and browse the Web from within an Access Form?

Not only Internet Sites, you can browse the Intranet Website within your Local Area Network - Corporate LAN) too. All you have to do is to create an Access Form with a Microsoft Web Browser Control and a few lines of VBA Code.

For example, the following VBA Code will open the GMail Web Site http://www.gmail.com/ automatically when you open the Form with the Web Browser Control, as shown in the above image.:

 
Private Sub Form_Load()
Dim strURL As String

      strURL = "http://www.gmail.com/"
      Me.WebBrowser0.Navigate strURL
End Sub

Don't know how to do it? Try the following:

Open a new Form in Design View.

Click somewhere on the Detail Section of the Form to select that area.

Select ActiveX Control... from Insert Menu.

Look for the name Microsoft Web Browser in the displayed list of ActiveX Controls and select it.

Click OK to insert a Web Browser Control on the Form.

While the Control is still in selected state drag the right-bottom-corner sizing control to make it big enough on the Form so that you can view the Web Pages properly.

Display the Property Sheet of the Browser Control (View - ->Properties).

Change the Name Property Value to WebBrowserO to match with the name used in the above VBA Code.

Select Code from View Menu to display the VBA Code Module of the Form.

Copy and Paste the above Code into the Module.

Save and Close the Form with the name myWebBrowser.

Connect your PC to the Internet.

Open myWebBrowser Form in normal View.

Wait for few seconds to load the Web Page into the Control and to display.

We have used the Website Address directly in the Code. But, if you create a Table with the list of all the Website addresses that you visit very often then with a Combo Box on the Form we can select the Web address to go to that site quickly. We need to make few changes in the above Code to make it flexible.

Create a Table with a single field with the following details:

WebSites

WebAddress

Text

255

Save the Table Structure and open it in Datasheet View.

Add few records with Web URLs that you visits frequently, save and close the Table.

Make a Copy of the Form myWebBrowser and name the copy as myWebBrowser2.

Open myWebBrowser2 in Design View.

Display the Form Header Section (View - -> Form Header/Footer), if it is not already Visible.

Expand the Form Header Section with enough height to create a Combo Box Control.

Create a Combo Box using the WebSites Table.

While the Combo Box is still in selected state display the Property Sheet (View - -> Properties).

Change the following Property Values of the Combo Box:


Name : cboWeb 
Width : 5" 
Default Value : "http://www.gmail.com/" or any other Website Address Value you prefer.

Select the child label attached to the Combo box and change the Caption Property Value to Web Address:

Display the Code Module of the Form (View - -> Code).

Copy and Paste the following Code into the Module replacing the existing lines.

 
Option Compare Database
Option Explicit

Dim WebObj As WebBrowser
Dim varURL As Variant

Private Sub cboWeb_Click()
     GotoSite
End Sub

Private Sub cboWebLostFocus()
     GotoSite
End Sub
 
Private Sub Form_Load()
     Set WebObj = Me.WebBrowser0.Object
GotoSite

End Sub

Private Function GotoSite()
    varURL = Me!cboWeb
If Len(Nz(varURL, "")) = 0 Then
    Exit Function
End If
 
WebObj.Navigate varURL

End Function

Save the Form and open it in Normal View.

The Website address that you have inserted into the Default Value Property of the Combo Box will open up in the Browser Control.

Select one of the other Website addresses you have added to the Table from the Combo Box.

The Browser Window will open the new Website.

If we open other Web Pages by clicking on the Links from the displayed pages then we can navigate (go Back or Forward) between pages by adding few more lines of Code.

But, first let us have a look at the above Code to see what is happening there. We have declared a Web Browser Object Variable and a Variant Variable at the Global declaration area of the Module.

Created a separate Function GotoSite() to respond to different Events (Actions) on the Form without duplicating the Code everywhere.

For example: when we open the Form the GotoSite() Function opens the Default Value URL, we set in the Combo Box Property, through the Form_Load() Event Procedure.

When you select a URL from the Combo Box the cboWeb_Click() Event Procedure calls this Function to open the selected Web Page.

If you type a URL in the Web Address Control cboWeb and moves the Cursor out of the control the Lost_Focus() Event Procedure runs the Function to open the URL you typed on the Address Control.

We will create few Command Buttons on the Header of the Form, as shown to the right of the Combo box Control on the above design and write Subroutines with some simple Browser Object Commands to navigate between Web Pages, which we may open from the displayed Web Pages.

Open myWebBrowser2 Form in Design View.

Display the Toolbox (if it is not visible then select Toolbox from View Menu.

Create five Command Buttons to the right of the Combo Box.

Display the Property Sheet of the first Command Button and change the Name Property and Caption Property Values to Home.

Similarly, change the Name and Caption Property Values of the other Command Buttons with the values given below.

Back

Forward

Refresh

Stop

Display the Code Module of the Form (View - ->Code), copy and paste the following Code into the VBA Module, below the existing Code lines.

 
Private Sub Home_Click()
On Error Resume Next
    WebObj.GoHome
End Sub

Private Sub Back_Click()
On Error Resume Next
    WebObj.GoBack
End Sub

Private Sub Forward_Click()
On Error Resume Next
    WebObj.GoForward
End Sub

Private Sub Refresh_Click()
On Error Resume Next
    WebObj.Refresh
End Sub

Private Sub Stop_Click()
On Error Resume Next
     WebObj.Stop
End Sub

The On Error Resume Next Statement prevents the Subroutines running into Error, when there are no Web Pages to Navigate to.

To test these Buttons you must click on few links on the displayed Web Page to open other Pages from the same Website and then use these Buttons to navigate between those opened pages.

The Home Button will open the Default Home page you set in the Internet Explorer's Tools - -> Internet Options… Home Page - -> Address Control, not the default Value you set in the Combo Box.

Filter Function Output in ListBox
Dynamic List Box Contents
Office Assistant and MsgBox Menus-3
Office Assistant and MsgBox Menus-2
Office Assistant and MsgBox Menus

Text Search Filter Web Style

noreply@blogger.com (a.p.r. pillai) — Sun, 20 Dec 2009 17:27:00 +0000

How to search for several pieces of information across all the fields and in all the records of a Table?

For example, when we search for something on the Web we give several piece of text separated with , or + symbol to match any of the given text anywhere within the Web Pages and display the matching links on the screen.

Search text example1 : ms-access, forms, reports, Queries

Or

Search text example2 : ms-access+forms+reports+queries

In the same way we can create filter to display records from a table that matches several piece of Text/numbers/Phrases across in any field in any record.

Last week we have learned the usage of BuildCriteria() Function to filter data using only one field. BuildCriteria() Function can accept only one Field as its first Parameter. We will be using this Function here also. But, we will pull a trick for using this Function for all the fields in a Table.

So let us do this with a simple Query and a Tabular Form.

Import Customers Table from C:\Program Files\Microsoft Offce\Office11\Samples\Northwind.mdb sample database.

Create a Query using the Customers Table with all the fields and by adding a new Column with the name FilterField.

Write the following expression in the new column to join all the Text and Numeric Field values together into a single Column:

FilterField: [CUstomerID] &" " & [CompanyName] &" " & [ContactName] & ...

HyperLinks, Objects

Yes/No

myQuery


Public Function CombineData(ByVal tblName As String)
'----------------------------------------------------------
'Author : a.p.r. pillai
'Date   : December 2009
'Rights : All Rights Reserved by www.msaccesstips.com
'----------------------------------------------------------
Dim strsql1 As String, db As Database, qrydef As QueryDef
Dim fldName As String, k As Integer, j As Integer
Dim tbldef As TableDef, strjoin As String

On Error Resume Next

strsql1 = "SELECT " & tblName & ".*, "
Set db = CurrentDb
Set qrydef = db.QueryDefs("myQuery")

Set tbldef = db.TableDefs(tblName)
k = tbldef.Fields.Count - 1

strjoin = ""
For j = 0 To k
    If tbldef.Fields(j).Type <> 1 And tbldef.Fields(j).Type <> 11 And tbldef.Fields(j).Type <> 12 Then
        If Len(strjoin) = 0 Then
            strjoin = "[" & tbldef.Fields(j).Name & "] "
        Else
            strjoin = strjoin & " & " & Chr$(34) & " " & Chr$(34) & " &  [" & tbldef.Fields(j).Name & "] "
        End If
    End If
Next

strsql1 = strsql1 & "(" & strjoin & ") AS FilterField FROM " & tblName & ";"
qrydef.SQL = strsql1
db.QueryDefs.Refresh

Set tbldef = Nothing
Set qrydef = Nothing
Set db = Nothing

End Function

Copy and paste the following VBA Code into a Standard Module and save it.

Display the VBA Debug Window (Ctrl+G).

Run the Program from the Debug Window by typing the following statement and pressing Enter Key:

CombineData "Customers"

myQuery

HyperLink, Object, Yes/No

Memo

Customers

FilterField

Memo

CombineData()

HyperLinks, Object

Memo

myQuery

Create a Tabular Form (continuous form) using myQuery as Record Source and save the Form with the name frmMyQuery.

Open the form frmMyQuery in Design view.

Select the FilterField Column and display its Property Sheet (View - ->Properties)

Change the Visible Property Value to No.

Make the FilterField column size very small on the Form (it is not visible on normal view) and resize other Columns to view their contents properly.

Remove the columns like Region, Fax etc. or any other column that you feel not required for our Test Runs, so that all the required columns will fit on one Screen properly.

Expand the Form Header Section and drag the column headings down so that we will get enough space to draw a Text Box and a Command Button beside it.

Create a Text Box above the column headings.

Display the Property Sheet of the Text Box (View - ->Properties).

Change the following Property Values as given below:

Name = txtSearch

Width = 3"

Change the Caption of the Child Label of the Text Box to Search Text (delimiter: , or +):

Create a Command Button to the right of the Text Box and change the following Property Values:

Name = cmdGo

Caption = GO>

Display the Code module of the Form (View - -> Code).

Copy and Paste the following VBA Code into the Module.


Private Sub cmdGo_Click()
'----------------------------------------------------------
'Author : a.p.r. pillai
'Date   : December 2009
'Rights : All Rights Reserved by www.msaccesstips.com
'----------------------------------------------------------
Dim x_Filter, j As Integer
Dim Y_Filter, Xchar As String, flag

x_Filter = Nz(Me![txtSearch], "")

If Len(x_Filter) = 0 Then
    Me.FilterOn = False
    Exit Sub
End If
'Code segment that tests and removes extra spaces'
'between coma and next search text item.

'--Extra space removal Segment start-
Y_Filter = ""
For j = 1 To Len(x_Filter)
    Xchar = Mid(x_Filter, j, 1)
' Test for presence of , or + and leading spaces
    If (Xchar = "," Or Xchar = "+") And Mid(x_Filter, j + 1, 1) = " " Then
            flag = True
    ElseIf Xchar <> " " And flag Then
            flag = False
            Y_Filter = Trim(Y_Filter)
    End If
    Y_Filter = Y_Filter & Xchar
Next
x_Filter = Y_Filter

'--Extra space removal Segment End-

Y_Filter = "*"
For j = 1 To Len(x_Filter)
        Xchar = Mid(x_Filter, j, 1)
      'Validation check
      If Xchar = "(" Or Xchar = ")" Then
                MsgBox "Invalid Characters () in expression, aborted... "
                Exit Sub
     End If
If Xchar = "," Or Xchar = "+" Then 'test for presence of ,+
     Xchar = "* OR *"
End If
Y_Filter = Y_Filter & Xchar
Next

Y_Filter = Y_Filter & "*"
Me.FilterOn = False
Y_Filter = BuildCriteria("FilterField", dbText, Y_Filter)
Me.Filter = Y_Filter
Me.FilterOn = True

End Sub

Save the Form and open it in Normal View.

Type some Text/Numbers/Phrases separated with comas (,) or plus symbol (+), which can match in any part of any Field(s) or in different Record(s), in the Text Box.

Example1: FRANK, Elizabeth Brown, Brazil

Example2: FRANK+Elizabeth Brown+Brazil

Example3: frank+ Elizabeth Brown, Brzail

NB:

()

BuildCriteria()

extra spaces

Click on the GO> Command Button to search for the given text in fields/records and filter those records on the Form.

You may inspect the filtered records to ensure that one or more of the search text you have entered into the Text Control appears in all the filtered records. They can appear in any field or fields in any Record, but all the records filtered will have these text/number/phrases on them.

Dynamic List Box Contents
Office Assistant and MsgBox Menus-3
Office Assistant and MsgBox Menus-2
Office Assistant and MsgBox Menus
Color and Picture in MsgBox

Filter with BuildCriteria Function

noreply@blogger.com (a.p.r. pillai) — Mon, 14 Dec 2009 19:16:00 +0000

Any method that helps to find data quickly on a Form is always welcome by Users. There are several options available when you are in Form View Mode.
When you Right-click on a Field a Shortcut Menu will popup showing four data filter options as shown on the sample image given below.

The third option Filter For can accept a Criteria Expression like >10200 AND <=10300 or similar to filter a Range of Values from the selected field.

If you would like to see more options then point on Filter option in Record Menu. There you can find two new Options: Filter by Form and Advance Filter/Sort. Filter by Form allows you to set up Criteria in more than one field to select records based on Form fields.

The Advance Filter/Sort will open up Filter Design (Query Design) Window with the Source Table/Query of the Form with whatever criteria you have entered into the Filter for or Filter by Form Options earlier, if any. You can further modify the filter conditions and Sorting Order and select Apply Filter from the Records Menu to view the result.

But, if you would like to build a Custom Filter Option for the User; based on a particular Field on the Form then you can use the built-in Function BuildCriteria() and write a VBA Sub-Routine around this Function to filter the data. Run the Sub-Routine on a Button Click Event Procedure and let the User input the Filter Criteria in various ways as he likes.

The Usage of the Function is very simple. Let us try few examples of the Function directly in the Debug Window (Immediate Window) to understand how it works.

Press Alt+F11 to display the Visual Basic Editing Window.

Press Ctrl+G to display the Debug window.

Type the following example expressions and press Enter key to display the output:

? BuildCriteria("OrderID",dblong,"10200")

Result: OrderID=10200

The BuildCriteria() Function needs three Function Parameters. OrderID is the Data Field Name, dbLong indicates that OrderID is a Numeric Field with values of Long Integer Type and the last Value 10200 is OrderID Criteria value for selecting records. The OrderID Field Name will be inserted in appropriate locations in the Criteria expression by the BuildCriteria() Function.

The last parameter value we can use in several ways depending on how we want the result. Let us see few more examples before we implement this method on a Form. Type the following expressions in the Debug Window to see how it works:

? BuildCriteria("OrderID",dblong, ">=10200 AND <10300")

Result: OrderID>=10200 And OrderID<10300

? BuildCriteria("OrderID",dblong,">=10200 AND <10300 OR >=10400 AND <10500")

Result: OrderID>=10200 And OrderID<10300 Or OrderID>=10400 And OrderID<10500

Try changing the data type to dbText, for example:

? BuildCriteria("OrderID",dbText,"10200")

Result: OrderID="10200"

? BbuildCriteria("OrderDate",dbDate,">10/15/2009 and <=10/31/2009")

Result: OrderDate>#10/15/2009# And OrderDate<=#10/31/2009#

After getting the result text from the BuildCriteria() Function all we have to do is to insert it into the Filter Property of the Form and turn ON the Filter action.

Let us design a simple Form to Run our example straight away.

Import the Orders Table from C:\Program Files\Microsoft Office\Officell\Samples\Northwind.mdb sample database.

Click on Orders Table to Select it and select Form from Insert Menu.

Select Auto Form:Tabular to create a Form and save it with the name Orders.

Open the Orders Form in Design View.

Expand the Form Header Area and drag all the Field Headings down to get enough room to create a Command Button above the Field Headings.

Display the ToolBox, if it is not visible (View - ->Toolbox).

Select the Command Button Tool and create a Command Button on the Header of the Form.

While the Command Button is still in selected state display its Property Sheet (View --> Properties).

Change the Name Property Value to cmdFilter and change the Caption Property Value to OrderID Filter.

Display the Code Module of the Form (View - -> Code).

Copy and Paste the following VBA Code into the Module.


Private Sub cmdFilter_Click()
Dim txtCondition, txtFilter As String

txtCondition = InputBox("OrderID Value/Range of Values")

If Len(txtCondition) = 0 Then
    Me.FilterOn = False
    Exit Sub
End If

txtFilter = BuildCriteria("OrderID", dbLong, txtCondition)

Me.FilterOn = False
Me.Filter = txtFilter
Me.FilterOn = True

End Sub

Save and Close the Form.

You may click on the OrderID Filter Command Button and enter any of the examples (except the one with Date) criteria expressions we have entered as third Parameter into the BuildCriteria() Function above, when prompted for the Filter Condition.

If you don't like to use InputBox() to prompt for Criteria Values then you may create a Text Box on the Form where Users can enter the Criteria expression before hitting on the Command Button.

The limitation of the BuildCriteria() Function is that it can accept only one field as first parameter. But, there is a way to use more than one field for the Filter condition on the Form. Ask the User to enter conditions for two different fields separately and run the BuildCriteria() Function also separately to obtain the results. Join both results with AND/OR Logical operators to filter the data.

The following example Code uses OrderID and ShipName field values to Filter data on the Orders Form.

Create a Copy of the Orders Form and name the Form as Orders2

Open the Form in Design View.

Display the Code Module of the Form ( View - -> Code).

Copy and Paste the following Code into the Module replacing the existing Code:


Private Sub cmdFilter_Click()
Dim txtOrderNumber, txtOrderfilter As String
Dim txtShipName, txtShipNameFilter As String
Dim msg As String, resp, txtFilter As String

txtOrderNumber = InputBox("OrderID Value/Range of Values to Filter")
txtShipName = InputBox("ShipName/Partial Text to Match")

If Len(txtOrderNumber) > 0 Then
txtOrderfilter = BuildCriteria("OrderID", dbLong, txtOrderNumber)
End If

If Len(txtShipName) > 0 Then
    txtShipNameFilter = BuildCriteria("ShipName", dbText, txtShipName)
End If

If Len(txtOrderfilter) > 0 And Len(txtShipNameFilter) > 0 Then
    msg = "1. Filter items-that matches both filter conditions" & vbCr & vbCr
    msg = msg & "2. Matches either one or Both conditions" & vbCr & vbCr
    msg = msg & "3. Cancel"
    Do While resp <> 1 And resp <> 2 And resp <> 3
        resp = InputBox(msg)
    Loop
    Select Case resp
        Case 3
            Exit Sub
        Case 1
            txtFilter = txtOrderfilter & " AND " & txtShipNameFilter
        Case 2
            txtFilter = txtOrderfilter & " OR " & txtShipNameFilter
    End Select
Else
    txtFilter = txtOrderfilter & txtShipNameFilter
    If Len(Trim(txtFilter)) = 0 Then
       Exit Sub
    End If
End If

Me.FilterOn = False
If Len(Trim(txtFilter)) > 0 Then
    Me.Filter = txtFilter
    Me.FilterOn = True
End If

End Sub

The first two InputBox() Functions collects the Filter Criteria for OrderID and ShipName Field values separately. Next steps Validates the User responses and Builds the criteria strings in txtOrderFilter and txtShipNameFilter Variables.

If both Variables have filter conditions in them then the User response is collected to check whether he/she needs the result set that meets both conditions (AND) or result set that meets any one of the conditions or both (OR).

The Filter Strings are joined accordingly to obtain the intended result. It is not necessary that the User should always provide both set of Criteria Values (for Orderld and ShipName) all the time. They can use only one Field for entering Criteria and ignore the other.

Office Assistant and MsgBox Menus-3
Office Assistant and MsgBox Menus-2
Office Assistant and MsgBox Menus
Color and Picture in MsgBox
Microsoft Excel Power in Access

Save User Specific Parameter values

noreply@blogger.com (a.p.r. pillai) — Sun, 06 Dec 2009 15:37:00 +0000

Last week we have prepared a Report Parameter Control Form for concurrent usage on Network without clashing with other User’s Report Data Filter Parameter Values, while preparing different Versions of the same Report. To do this we have discarded the usage of a Parameter Table as Record Source to the Parameter Form and created two Unbound Text Boxes for keying in Parameter Values for setting Filter condition in the Report Source Query. Besides that we have seen how to save the Parameter Values in the Custom Properties of the Form, when the Form is closed.

The sample image of the Report Parameter Form: RptParameter is given below for reference:

Last week we have used the Parameter Control's Text Box Names FromDate and ToDate for entering Date-Range values as Criteria for filtering Data in Report Source Query. The Custom Property Names we have created giving slight change to the Text Box Names, like DateFrom and DateTo.

One Question we have raised last week was; is it possible to Save and Retrieve the Report Parameter Values set by each User on the fromDate and toDate Text Box Controls, in different instances of the same Form, without getting overwritten by somebody else value. In last week's example the survivor of the values written to the Custom Properties are the values of the last User who closes the Parameter Form.

The solution is simple; create Custom Properties on the Form for each User and save the value set by him/her when their side instance of the Parameter Form is closed. To identify each User's value; add the User-Name along with the TextBox Name and create the Custom Property Name with that combined text value.

For example:


 User-Name               :  JSmith

        Parameter TextBox Name1 :  fromDate
        Parameter TextBox Name2 :  toDate

        Custom Property Name1   :  JSmithDateFrom
        Custom Property Name2   :  JSmithDateTo

We can get the User Name of the current instance of the Form with the Function CurrentUser().

When the User-Name is prefixed to the Custom Property Names we can easily save and retrieve individual User's parameter values and use on their instance of the same Form as well.

Another point we have to keep in mind is that new Users may be added to the same Workgroup and this method should work for them also, when they start using the RptParameter Form.

We must write the VBA Routines in such a way that whenever a new User starts working with the RptParameter Form; the User must be identified as a new comer and Custom Properties for that User must be created automatically, rather than creating it manually as we did in the earlier example.

The modified Custom Properties creation Program is given below. Copy and Paste the Code into a Standard Module of your Database.


Public Function CreateCustom_Property(ByVal frmName As String, ByVal usrName As String)
‘-------------------------------------------------------------------------
‘ Author : a.p.r. pillai
‘ Date   : November-2009
‘ All Rights Reserved by www.msaccesstips.com
‘-------------------------------------------------------------------------
Dim cdb As Database, doc As Document
Dim prp As Property, getPrpValue
Dim fld1 As String, fld2 As String

On Error Resume Next

fld1 = usrName & "DateFrom"
fld2 = usrName & "DateTo"

Set cdb = CurrentDb
Set doc = cdb.Containers("Forms").Documents(frmName)

'check whether the Property of the current user exists
getPrpValue = doc.Properties(fld1).Value

If Err = 3270 Then ' referenced Property doesn't exist
    Err.Clear
    'create Property for new User
    Set prp = doc.CreateProperty(fld1, dbDate, Date)
    doc.Properties.Append prp
    Set prp = doc.CreateProperty(fld2, dbDate, Date)
    doc.Properties.Append prp
    doc.Properties.Refresh
End If

Set prp = Nothing
Set doc = Nothing
Set cdb = Nothing

End Function

Create a Copy of the RptParameter Form with the name RptParameter2.

Open RptParameter2 Form in Design View.

Display the VBA Module of the Form (View - -> Code).

Copy and Paste the following Sub-Routines into the VBA Module overwriting the earlier Code:


Private Sub Form_Load()
Dim cdb As Database, doc As Document
Dim fld1 As String, fld2 As String

fld1 = CurrentUser & "DateFrom"
fld2 = CurrentUser & "DateTo"

'Validate Current User's Status
'If, necessary create Custom Properties for new User
CreateCustom_Property Me.Name, CurrentUser

DoCmd.Restore

Set cdb = CurrentDb
Set doc = cdb.Containers("Forms").Documents(Me.Name)

Me![fromDate] = doc.Properties(fld1).Value
Me![toDate] = doc.Properties(fld2).Value

Set cdb = Nothing
Set doc = Nothing

End Sub



Private Sub Form_Close()
Dim cdb As Database, doc As Document
Dim fld1 As String, fld2 As String

fld1 = CurrentUser & "DateFrom"
fld2 = CurrentUser & "DateTo"

Set cdb = CurrentDb
Set doc = cdb.Containers("Forms").Documents(Me.Name)

doc.Properties(fld1).Value = Me![fromDate]
doc.Properties(fld2).Value = Me![toDate]

Set cdb = Nothing
Set doc = Nothing
End Sub

Save and Close the Form.

As you can see from the Form_Load() Event Procedure that the Custom Property Creation Program CreateCustom_Property() is called only when the User (New or existing) opens the RptParameter2 Form. So, the Custom properties are not created for all the Users of the Database if their activity doesn't involve this particular Form.

The Report Parameter Form must be tested from different machines at the same time by different Users and set their own values in the Parameter Control Text Boxes: fromDate and toDate to try out the procedure. When the Form is open by the same Users next time the values set by them in the earlier session should appear in fromDate and toDate Text Box Controls.

NB: The above Procedure is not extensively tested to trap Bugs or side effects and you may use it at your own risk. If you find any Bugs or issues please share it with me too. The procedure assumes that the Database is implemented with Microsoft Access Security.

Visit the Page: Unsecured Database and Users Log to find out how to get User's Name when the shared database is an Un-secured one. In un-secured databases the CurrentUser() Function will always return the User Name as Admin.

Office Assistant and MsgBox Menus-2
Office Assistant and MsgBox Menus
Color and Picture in MsgBox
Microsoft Excel Power in Access
Un-secured Database and Users-Log

Creating Using Form Custom Property

noreply@blogger.com (a.p.r. pillai) — Sun, 29 Nov 2009 18:11:00 +0000

Parameter Controls are provided to the Users for entering data Filter criteria values for preparing MS-Access Reports. A reference to the parameter control fields can be set in the criteria row of the Report Source Query directly to filter the data. A sample image of such a Parameter Control is given below.

The above Report Parameter Control gives flexibility to the User to set a Date Range in the fields provided on the screen before opening one of two Report Options provided. When the User Clicks on the Preview Command Button the Report will be opened with data filtered using the Parameter Control Date Range values set as Criteria on the Source Query.

To record the Date Range values (Date From and Date To) a small Table with two fields is created with a single record and used as Record Source to the above Form. The idea behind the use of a Table is to preserve the last used Report Parameter Values in the Table. Next time when we open the Form we will know for which period we have prepared the Report earlier. The parameter table can also be used in the Query to link with the Data Table or use its value as criteria in the criteria Row of the Report Source Query. The following two Form Property Values must be set as shown below to prevent adding new Records to the Table and not to delete the existing one:

This method works fine when the Database is a Single User one.

But, when the database is shared on a Network there is a problem to this method. Different Users may open the same Parameter Screen at the same time to prepare their version of the same Report. They will attempt to change the parameter values at the same time. This action will end up with a record edit lock error or the values set can cross over and the Report printed can go wrong too. Even though the Users can open different instances of the same Form on their machines the Record Source Table is same.

We are focusing on this particular aspect to see how we can safely provide the above Parameter Control to the Users to work safely without clashing each other.

Perhaps, you have the right solution to this problem by now. Yes, do not use the Parameter Table to store the Report criteria values; instead create two Unbound Text Boxes on the Form, as you have rightly guessed. This will ensure that all Users will work independently on their own instances of the Report Parameter Form and no chance of clashing with each other's values.

There is only a minor draw back in this method; you cannot store the last used Report Parameter Value anywhere so that it will be displayed next time when you open the Form.

At least one set of value is required when you open the Form next time. If these controls remain empty and if you run the Preview option without setting the parameter values then the Report will be empty and will end up showing #Error in all controls with expressions created for Summary Values.

I have already published an Article on this topic earlier as how to open the Report without this Error condition when the Report Source Query or Table is empty. Click here to find out.

We can save the values, from the Unbound Text Box controls, on the Parameter Form itself in Custom Properties, which we can create on the Form. Managing data in Custom Properties can be done only through VBA and these Property Names and their Values are not visible on the Property Sheets that we normally work with.

Click here to find out more details on Custom Properties and a method that we have used earlier to open the Form with last edited record as current on the Form.

We have to go through the following procedure to manage the User data on the Form itself without the use of a Table as Record Source:

Create two Custom Properties on the Form with the names DateFrom and DateTo with the Data Type Date/Time and with an initial Value.

Name

When the Parameter Form is closed after normal use the values set on the Unbound Text Boxes are Saved into the Custom Properties during the Form Close Event.

The saved values are loaded back into the Unbound Text Boxes from the Custom Properties when the Report Parameter Form is open next time.

To try out this method, open a new Form and create two Unbound Text Boxes.

Click on the first Text Box and display its Property Sheet (View - -> Properties).

Change the Name Property Value to fromDate.

Change the Name Property Value of the second Text Box to toDate.

Close and save the Form with the name RptParameter.

Display the VBA Editing Window (Alt+F11), copy and paste the following VBA Code into the Standard Module. If necessary, create a new Module (Insert - -> Module).


Public Function CreateCustomProperty()
Dim cdb As Database, doc As Document
Dim prp As Property

Set cdb = CurrentDb
Set doc = cdb.Containers("Forms").Documents("RptParameter")

Set prp = doc.CreateProperty("DateFrom", dbDate, Date)
doc.Properties.Append prp

Set prp = doc.CreateProperty("DateTo", dbDate, Date)
doc.Properties.Append prp

doc.Properties.Refresh

Set prp = Nothing
Set doc = Nothing
Set cdb = Nothing

End Function

Click somewhere within the pasted VBA Code and press F5 to Run the Code and create two Custom Properties with the Names DateFrom and DateTo with the Data Type Date/Time and with the initial value of System Date.

Delete


Public Function DeleteCustomProperty()
Dim cdb As Database, doc As Document
Dim prp As Property

Set cdb = CurrentDb
Set doc = cdb.Containers("Forms").Documents("RptParameter")

doc.Properties.Delete "DateFrom"
doc.Properties.Delete "DateTo"
doc.Properties.Refresh

Set prp = Nothing
Set doc = Nothing
Set cdb = Nothing

End Function

Open the RptParameter Form in Desgin View.

Display the VBA Code Module of the Form (View - -> Code).

Copy and Paste the following two Sub-Routines into the Form Module and save the Form:


Private Sub Form_Close()
Dim cdb As Database, doc As Document

Set cdb = CurrentDb
Set doc = cdb.Containers("Forms").Documents("RptParameter")

doc.Properties("DateFrom").Value = Me![fromDate]
doc.Properties("DateTo").Value = Me![toDate]

Set cdb = Nothing
Set doc = Nothing

End Sub




Private Sub Form_Load()
Dim cdb As Database, doc As Document

DoCmd.Restore

Set cdb = CurrentDb
Set doc = cdb.Containers("Forms").Documents("RptParameter")

Me![fromDate] = doc.Properties("DateFrom").Value
Me![toDate] = doc.Properties("DateTo").Value

Set cdb = Nothing
Set doc = Nothing

End Sub

Open the RptParameter Form in Normal View and enter some Date Range values into fromDate and toDate Unbound Text Boxes.

Even after implementing this method I am not fully happy with it. Because, it will preserve only one of the Values, set by different Users working with the Form at the same time.

What I would like to see as a User is that the last value that I set on the Report Parameter Field is appearing on the Form again when I open the Form next time, not the value set by someone else. Is it possible? Yes, it is possible. We will see how to do this next week.

Office Assistant and MsgBox Menus
Color and Picture in MsgBox
Microsoft Excel Power in Access
Un-secured Database and Users-Log
MS-Access Report and Page Total

MS-Access And Data Processing-2

noreply@blogger.com (a.p.r. pillai) — Sun, 22 Nov 2009 17:21:00 +0000

This is the continuation of earlier Article published on this subject last week. Click here to visit that Page.

Last week we have explored the sample data processing methods and tried to approach the same problem in different ways to arrive at the same result. Reports are the main output component that goes to the User with critical information for analysis of business activities and for making serious business decisions. Transforming raw data into meaningful form and providing them on Reports is a real challenge of any Project.

If you attain some working knowledge of different types of Queries available in MS-Access you can do most of these tasks without touching the VBA Code. Depending upon the complexity of processing steps you can use several Queries, create intermediate temporary Tables and use those tables as source for other Queries to overcome issues that may arise as hurdles in the processing steps.

We will look into such an issue here so that you will know what I meant by hurdles in creating the final Report. Such complex data processing steps can be automated by sequencing each step in a Macro and run that Macro from a Command Button Click or from VBA Sub-Routines.

It is absolutely necessary to create and maintain Flow Charts of process that involves several Queries and Tables for Reports. You may create hundreds of Queries in a Database for different Reports. After some time we may forget what we did for a particular Report. If the User points out any flaw in the output then we can easily back track the steps using the Flow Chart and debug the problem.

Last week I have raised a question as how we will show Revenue, Expenses and Profit/Loss month-wise if the sample data are added with Year and Month Fields. The image of the sample Table (Transactions2) Source data is given below:

The image of the Report Output Created and presented to you last week is shown below:

We can transform the sample data given in the first image above into the Report output form in the second image in two steps. The numbers appearing as Suffix to the Column headings represents the Month Value. For example, Revenue1 is January Revenue and Profit/Loss2 is of February.

We can arrive at the above result in two steps and the SQL String of those two Queries are given below:

Query Name: Method2_1


TRANSFORM Sum(Transactions2.Amount) AS SumOfAmount
SELECT Transactions2.Location, Transactions2.Year
FROM Transactions2
GROUP BY Transactions2.Location, Transactions2.Year
PIVOT IIf([type]="R","Revenue","Expenses") & [Month];

Copy and Paste the above SQL String into the SQL Editing Window of a new Query and save it with the name Method2_1.

Open the Query and view the output as how it is transformed with the Cross-Tab Query.

Method2_2


SELECT Method2_1.Location, Method2_1.Year, 
Method2_1.Revenue1, Method2_1.Expenses1,
 [Revenue1]-[Expenses1] AS [Profit/Loss1],
 Method2_1.Revenue2, Method2_1.Expenses2,
 [Revenue2]-[Expenses2] AS [Profit/Loss2]
FROM Method2_1;

Copy and Paste the above SQL String into the SQL Editing Window of a new Query and save it with the name Method2_2.

Query

Report

Open Method2_2 Query and view the output.

Even though we could arrive at the sample result with the above two Queries we have to modify the second Query every time to create Profit/Loss Column when new data records are added for subsequent months. The P & L Report if created using the second Query then that also has to undergo changes to add Revenue, Expenses and Profit Columns for the new period.

This cannot be a good method when we are expected to automate every process in the Database so that the User can prepare Reports with the click of a Button.

We can automate this data processing task permanently with the following few simple steps:

Create a second Report Table with Revenue and Expenses Fields for all twelve months.

Change the second Query created above (Method2_2) as an append query and add the output data of available months into the Report Table.

Create a SELECT Query using the Report Table as source to calculate Profit/Loss Values for all twelve months only once. This is possible because we have all twelve month's data fields in the Report Table, even if some of them will have only zero values till December.

Design the P&L Report with all twelve months Revenue, Expenses&Profit/Loss Fields using the Query created in Step-3 as source.

Once you implement this method you don't have to make any changes to the Queries or Report when new data records are added in the Source Table. All you have to do is to automate this process, like deleting the old data (for this action we will need a Delete type Query) from the Report Table and bringing in fresh Report data from source table Transactions2.

So, let us get to work and do it.

Create a Table with the following Field Structure and save it with the name PandLReportTable.

R12

E12

Revenue

Expenses

January

December

NB:

Default Value

Number

Property Sheet

Null

Copy and paste the following SQL String into a new Query's SQL Editing Window and save it with the name Method3_l.


TRANSFORM Sum(Transactions2.Amount) AS SumOfAmount
SELECT Transactions2.Location, Transactions2.Year
FROM Transactions2
GROUP BY Transactions2.Location, Transactions2.Year
PIVOT [type]&[Month];

Copy and paste the SQL string given below into a new Query and save it with the name Method3_2.


INSERT INTO PandLReportTable
SELECT Method3_1.*
FROM Method3_1;

Copy and paste the following SQL String into a new Query and save it with the name PandLReportQ.


SELECT PandLReportTable.Location, PandLReportTable.Year, 
PandLReportTable.R1, PandLReportTable.E1, [R1]-[E1] AS P1,
 PandLReportTable.R2, PandLReportTable.E2, [R2]-[E2] AS P2, 
PandLReportTable.R3, PandLReportTable.E3, [R3]-[E3] AS P3, 
PandLReportTable.R4, PandLReportTable.E4, [R4]-[E4] AS P4, 
PandLReportTable.R5, PandLReportTable.E5, [R5]-[E5] AS P5,
 PandLReportTable.R6, PandLReportTable.E6, [R6]-[E6] AS P6,
 PandLReportTable.R7, PandLReportTable.E7, [R7]-[E7] AS P7, 
PandLReportTable.R8, PandLReportTable.E8, [R8]-[E8] AS P8, 
PandLReportTable.R9, PandLReportTable.E9, [R9]-[E9] AS P9, 
PandLReportTable.R10, PandLReportTable.E10, [R10]-[E10] AS P10, 
PandLReportTable.R11, PandLReportTable.E11, [R11]-[E11] AS P11, 
PandLReportTable.R12, PandLReportTable.E12, [R12]-[E12] AS P12
FROM PandLReportTable;

Design a Report using PandLReportQ as Source File, like the sample design image given below.

January

February

Year

Report

Revenue

Expenses

Delete Query

PandLReportTable

Create a new Query with the following SQL String and name the Query as PandLReportTable_Init.


DELETE PandLReportTable.*
FROM PandLReportTable;

Isn't it easy enough to prepare the P&L Report with the above simple Queries and with a supporting Report Table for any number of Locations that you add to your main Source Table Transactions2. As you can see now you don't need any complicated programs to prepare this Report.

If you look at the Queries we have created we can see that there are only two Action Queries among them (Delete and Append Queries). We can put these two Queries into a Macro to automate the P&L Report preparation easily. But first, let us examine the logical arrangement of this Report preparation procedure with a Process Flow Chart.

In Step-1 the PandLReportTable_Init Query removes earlier Report Data from the PandLReportTable.

In Step-3 the Append Query (Method3_2) takes the Cross-Tab Query output from Step-2 and adds them to the Report Table PandLReportTable.

We have already written expressions in PandLReportQ SELECT Query to calculate Profit/Loss Values. The Report will automatically get all available data from this Query and other Columns on the Report will remain empty till fresh data Records are added in the Source Table Transactions2.

If we can add both the Action Queries into a Macro (or VBA Subroutine) then the User can click on a Command Button to run it every month to create the Report with added data within seconds.
The sample image of the Macro with the Action Queries in sequence is given below for reference:

If you can further simplify this procedure please share that idea with me too?

Color and Picture in MsgBox
Microsoft Excel Power in Access
Un-secured Database and Users-Log
MS-Access Report and Page Total
Detail and Summary from Same Report

MS-Access and Data Processing

noreply@blogger.com (a.p.r. pillai) — Sun, 15 Nov 2009 16:41:00 +0000

Designing Forms or Reports can be learned quickly by mastering the usage of Design Tools available in MS-Access, keeping aside the programming aspects. But, data processing is something that demands diversity in each Project and cannot be standardized. The data Table design is very important and these must be carefully planned and created for easier retrieval of information as well as to avoid duplication. Proper relationships must be established between Tables to join related information together.

Ignoring the importance of these considerations, designing with casual approach and filling up data in them like you do in Microsoft Excel will land you in trouble when you attempt to prepare reports out of them.

You can see a good example of database design in the C:\Program Files\Microsoft Office11\Samples\Northwind.mdb sample Database.

Open this sample database and select Relationships from Tools Menu to view the structure of various Tables and how they are organized and related one another. Use it as a reference point and guide when you plan for a new Project.

Each Field Name in bold is defined as Primary Key in their respective Table and established One-to-many Relationships to one another. This will ensure the availability of required information when needed from related tables for Reports.

The above lines were only a reminder to your future projects. You can see an example image of a bad Table design below. The Location names and Description values should have been in Tables of their own with appropriate Codes. Two Combo Boxes can be created in the Transactions Table Structure to insert those Codes into the fields to avoid duplication of information as shown below.

But here, we are going to concentrate on learning the data processing steps using the above Table.

The second data field Type contains transaction type Codes. R stands for Revenue and E for Expenses. These category Codes are introduced in the Table keeping in mind that we must be able to Group the transactions on Category and Tabulate the Revenue and Expenses Values separately. The Description field shows the actual Account Heads under which each transaction is recorded.

We have been asked to prepare a Location-wise Profit/Loss Statement. Subtracting the Total of all Expenses from the Total of all Revenue figures will give us the required result. How many Queries or steps you require to solve this problem, any idea? We require only the final Profit/Loss value with the Location Name on the Report, like the image below:

The first thought in your mind, I presume may be, how you can subtract the value of one Row from the other. Then you are thinking on the right direction.

If you say in four steps I will not accept that as a good approach but if you can solve the problem and come out with the result then that is OK with me. After all, the correct end-result is all that matters as far as the User is concerned.

If you say in three steps I will be happy to see you how you do it. If you say in two steps then I know you have some grip on things around here. If you say in one step then I know you are somebody with MS-Access.

If you are really interested in taking up this simple challenge then stop reading further down from here and start trying out this in a database of your own. Come back with your own solution and compare it on the examples given here. If you do it differently, but arrived at the same result then share that idea with me too.

Create the Transactions Table with the Structure and sample data given above.

One Step solution

Copy the following SQL String into the SQL Editing Window of a new Query and save it with a name you prefer.


SELECT Transactions.Location, Sum(IIf([type]="E",-[Amount],[Amount])) AS Profit
FROM Transactions
GROUP BY Transactions.Location;

Open the Query in Normal View and you will see the result of the Query as shown in the second Image given above.

Two Step solution

Create a Query with the following SQL String and name the Query as Query_Step1.


SELECT Transactions.*, IIf([Type]="E",-[Amount],[Amount]) AS Amt
FROM Transactions;

Tip:

The Query Amt Column is formatted to display Negative Values in Color and in brackets. Open the Query in Design View. Highlight the Column and click on the Properties Toolbar Button or select Properties from View Menu to display the Property Sheet of the Column. Type 0.00;[Red](0.00);0.00;0.00 into the Format Property and save the Query. If you open the Query now the output will appear in color.

The Format Property Values are expressed in four segments separated with semi-colons. First segment dictates how to display positive values, second segment stands for Negative values, third segment says what to display when the field value is Zero and fourth segment displays zero when the Field/Column contain Null. Third and fourth segments can be set with a literal string like 0.00;[Red](0.00);"Zero";"Null" to display these values rather than 0.00. You can set the Field Format Property values on the Table Structure, on Forms or on Reports. It is not necessary that you should use all the four segments of the Format Property Values all the time.

Create another Query, with the following SQL String, using Query_Step1 as Source Data and save the Query with the name PL_Report:
```
SELECT Query_Step1.Location, Sum(Query_Step1.Amt) AS Amount
FROM Query_Step1
GROUP BY Query_Step1.Location;
```
Open the PL_Report Query in normal view and the result will be same as the second image given above.

Three Step Solution

If you need more clarity in how the results are being formed for the final report then try this method.

You can use the first Query under the two steps solution as the first step here.

Use the following SQL String, that uses the first step Query's output as source data, and create the second step Query with the name Query_Step2:


SELECT Query_Step1.Location, Query_Step1.Type, Sum(Query_Step1.Amt) AS Amt
FROM Query_Step1
GROUP BY Query_Step1.Location, Query_Step1.Type
ORDER BY Query_Step1.Location, Sum(Query_Step1.Amt) DESC;

Create a third Query for the final result, with the SQL String given below, using the second step Query (Query_Step2) as Input:


SELECT Query_Step2.Location, "Profit/Loss" AS Description, Sum(Query_Step2.Amt) AS Amt
FROM Query_Step2
GROUP BY Query_Step2.Location;

The output of the above Query is given below with a three Column result replacing Type Column with Description.

How about doing it differently and arrive at the following Result with Queries in two Steps?

Create the first Query Method2_1 with the following SQL String:


TRANSFORM Sum(Transactions.Amount) AS SumOfAmount
SELECT Transactions.Location
FROM Transactions
GROUP BY Transactions.Location
PIVOT IIf([Type]="R","Revenue","Expenses");

Create the Report Query Method2_2 with the following SQL String that uses Method2_1 as Source:


SELECT Method2_1.Location, Method2_1.Revenue, Method2_1.Expenses, [Revenue]-[Expenses] AS [Profit/Loss]
FROM Method2_1;

Open Method2_2 Query in Normal View and check the output.
As you have seen in the above examples you can approach a problem in MS-Access differently and arrive at the same result. If you have to create several steps to get the final Report output, then it is a good idea to create a Flow Chart of the Process Steps. Later on if you find something is not right with the Report you can always follow this path and back-track to find the Error.

A sample Flow Chart of the Three Step Solution is given below:

If the Transactions Table has Year and Month Fields too and both locations have January and February 2009 data in them then how you will create the Report Month-wise?

Try it out on your own and check it out with my examples next week. Sample image of the output is given below for reference.

Microsoft Excel Power in Access
Un-secured Database and Users-Log
MS-Access Report and Page Total
Detail and Summary from Same Report
Hiding Report Lines Conditionally-3

Form Bookmarks And Data Editing-3

noreply@blogger.com (a.p.r. pillai) — Sun, 08 Nov 2009 16:24:00 +0000

This is the continuation of our discussion on the usage of Form Bookmarks to revisit the records which we have already visited earlier. The links to the earlier Articles are given below:

Form Bookmarks And Data Editing

Form Bookmarks And Data Editing-2

The discussion on Bookmarks is not complete without touching the subject of Searching and Finding records and showing it as Current Record on Form using RecordsetClone.

In our earlier examples we have used the Find Control (Ctrl+F or Edit - ->Find…) to search for a record and when found save its Bookmark in an Array Variable in Memory for later use.

This time we will use a different method to find the record and bring it on the Form with the use of Bookmark of the RecordsetClone of the Form.

For this method we will use an Unbound Text Box to enter the search key value and a Command Button to click and find the record. To keep the VBA Code simple this time we will use the Customers Table rather than Order Details table, because Order Details Table have several records with the same OrderIDs.

If we use Order Details table then we have to combine the ProductID with OrderID to form a unique value to retrieve a specific record among several records with the same OrderIDs. This method we have already used in the earlier example to select and display all the records we have retrieved and edited.

As I have pointed out in the earlier Articles, when we open a Form with a Table, Query or SQL Statement each record on the Form is marked by MS-Access with a unique identification tag known as Bookmark. We can create a copy of this Recordset into memory (RecordsetClone) and work with it independently. Using the RecordsetClone, with the Form Bookmark attached to each record, we can find the required record with VBA Code using the search Key Value. Once we find the target record in memory we can read that record's Bookmark and insert it into the Form's Bookmark Property to make that record current on the Form.

But remember, you cannot read the Form's Bookmark Property Value and insert it into the RecordsetClone to find the same record in memory.

On the User's point of View all she has to do is to enter the Search Key Value (CustomerID) into the Unbound Text Box and click the Command Button next to it to find that record and bring it up on the Form.

Look at the sample VBA Code given below that runs on the Command Button Click (with the Name cmdFind) after setting the Search Key Value (CustomerID) in an Unbound Text Box with the name xFind.

Private Sub cmdFind_Click()
Dim m_Find, rst As Recordset

m_Find = Me![xFind]

Set rst = Me.RecordsetClone

rst.FindFirst "CustomerID = '" & [m_Find] & "'"

If Not rst.NoMatch Then
Me.Bookmark = rst.Bookmark
End If

End Sub

The line that reads Set rst = Me.RecordsetClone copies the Form's Recordset into the Recordset Object Variable rst in Memory and the next line runs the FindFirst method of the Recordset Object to search and find the record with the given CustomerID Value.

In the next three lines we are testing whether the rst.FindFirst method was successful in finding the record or not. If found then the Bookmark of the current record in the Recordset is transferred to the Bookmark Property of the Form to make that record Current on the Form.

I have already published an Article on this method few months back with the Title: Animating Label on Search Success. You may visit that Page to copy the complete VBA Code of the Sub-Routine given above and try them out.

You must import the Customers Table and Customers Form from C:\Program Files\Microsoft Office\Office11\Northwind.mdb sample Database and modify the Form to add a Text Box and a Command Button at the Footer of the Form.

When the rst.FindFirst method finds the record and makes it current; a Label at the bottom of the Unbound Text Box will flash few times with a message indicating that the search operation was successful and that record is made Current on the Form. If the search operation failed then the Label will flash few times with the message: Sorry, not found.

This method added to the above program gives the User a quick indication whether the search was successful or not. To go to the Page to try out the Program Click here.

Un-secured Database and Users-Log
MS-Access Report and Page Total
Detail and Summary from Same Report
Hiding Report Lines Conditionally-3
Hiding Report Lines Conditionally-2

Form Bookmarks And Data Editing-2

noreply@blogger.com (a.p.r. pillai) — Sun, 01 Nov 2009 17:23:00 +0000

In the first part of this Article, we were using the saved Bookmarks to revisit the earlier visited records one by one to take a second look, if it became necessary, to ascertain the accuracy of edited information.

The Function myBookMarks() that we have created for this purpose can be added with one more Option, (along with 1=Save Bookmark, 2=retrieve Bookmarks, 3=initialize Bookmark List) to display all the edited records together in Datasheet View.

But, this method has some side effects and must be aware of it to implement some work around methods in such situations. Here, we will try that with the Order Details Table.

In the last example we were using the Bookmark Index Number and OrderID number values as a guide to cross check with the retrieved record.

Several Products can be ordered under the same Purchase Order and all Products under the same Order will bear the same OrderIDs too. If OrderIDs are alone used in a Query Criteria to retrieve the records then all records with the same Order IDs will be displayed, irrespective of which record among them we have visited earlier.

There were no such issues when we were using Bookmarks of each record to find them again and OrderIDs were used only as a guide to cross check the retrieved record’s identity.

But here, we are trying to use the OrderId Values saved in the Combo Box List as Criteria in a Query to retrieve all the edited records at one go.

This problem we can overcome if some other unique value, if available, is used in the Combo Box list. Or use one or more field values combined to form a unique value for each record and save it in the Combo Box List along with the Bookmark Index Number. This is what we are going to do now with the 4th Option of myBookMarks() Function.

We will use OrderID with ProductID combined Values and save them in the Combo Box List. The same Product Code will not appear twice under the same Purchase Order. This will ensure that the values saved in the Combo Box are unique.

The idea behind this new method is to create a Dynamic Query using the Values saved in the Combo Box list and open the Query with all the edited records from the Order Detail Table with one click.

In the fourth Option of the Function myBookMarks() we will build an SQL String using the Values saved in the Combo box as Criteria and modify the SQL string of a SELECT Query to retrieve the records. We have to create another Command Button near the << Reset Button to run this Option, so that the User can click on it to retrieve all the edited records and display them in Datasheet View at his will.

But, first let us write the Code Segment that implements this particular Option. We need few Objects and Variable declarations at the declaration section of the Function.

Dim db as Database, QryDef as Querydef
Dim strSql as String, strSqltmp as String, strCriteria as String
.
.
.
Select Case ActionCode
.
.
.
Case 1
.
Case 2
.
Case 3
.
Case 4
strSqltmp = "SELECT [Order Details].* "
strSqltmp = strSqltmp & "FROM [Order Details] "
strSqltmp = strSqltmp & "WHERE ((([OrderID]" & "&" & Chr$(34)
strSqltmp = strSqltmp & "-" & Chr$(34) & "&" & "[ProductID]) In ('"

strCriteria = ""
For j = 0 To ArrayIndex - 1
If Len(strCriteria) = 0 Then
strCriteria = ctrlCombo.Column(1, j)
Else
strCriteria = strCriteria & "','" & ctrlCombo.Column(1, j)
End If
Next
strCriteria = strCriteria & "')));"

Set db = CurrentDb
Set Qrydef = db.QueryDefs("OrderDetails_Bookmarks")
strSql = strSqltmp & strCriteria
Qrydef.SQL = strSql
db.QueryDefs.Refresh
DoCmd.OpenQuery "OrderDetails_Bookmarks", acViewNormal
End Select

We are creating part of the SQL string that remains constant in the strSqltmp. Extracting the Combo Box 2nd Column Values (combined values of OrderID and ProductID separated with a hyphen character) and building the Criteria part of the Query in the String Variable strCriteria within the For…Next Loop. Finally we are redefining the SQL of the OrderDetails_BookMarks Query before opening it with the extracted Records.

The Combo Box Columns have Zero based Index Numbers and the second Column Index number is 1. So the statement strCriteria = strCriteria & "','" & ctrlCombo.Column(1, j) takes the second column value OrderID and PrductID combined String value for criteria.

The modified Code of the myBookMarks() Function with the above Option is given below.

You may Copy the Code and Paste it in the Standard Module replacing the earlier Code or rename the earlier Function and save this Code separately.


Public Const ArrayRange As Integer = 25
Dim bookmarklist(1 To ArrayRange) As String, ArrayIndex As Integer

Public Function myBookMarks(ByVal ActionCode As Integer, ByVal cboBoxName As String, Optional ByVal RecordKeyValue) As String
'-----------------------------------------------------------------
'Author : a.p.r. pillai
'Date   : October-2009
'URL    : www.msaccesstips.com
'Remarks: All Rights Reserved by www.msaccesstips.com
'-----------------------------------------------------------------
'Action Code : 1 - Save Bookmark in Memory
'            : 2 - Retrieve Bookmark and make the record current
'            : 3 - Initialize Bookmark List and ComboBox contents
‘            : 4 – Filter Records and display in Datasheet View
'-----------------------------------------------------------------
Dim ctrlCombo As ComboBox, actvForm As Form, bkmk As String
Dim j As Integer, msg As String, bkmkchk As Variant
Dim strRowSource As String, strRStmp As String, matchflag As Integer
Dim msgButton As Integer

Dim db As Database, Qrydef As QueryDef
Dim strSql As String, strSqltmp As String, strCriteria As String

'On Error GoTo myBookMarks_Err

If ActionCode < 1 Or ActionCode > 4 Then
   msg = "Invalid Action Code : " & ActionCode & vbCr & vbCr
   msg = msg & "Valid Values : 1 to 4"
   MsgBox msg, , "myBookMarks"
   Exit Function
End If

Set actvForm = Screen.ActiveForm
Set ctrlCombo = actvForm.Controls(cboBoxName)
Select Case ActionCode
    Case 1
        bkmk = actvForm.Bookmark
        'check for existence of same bookmark in Array
        matchflag = -1
        For j = 1 To ArrayIndex
           matchflag = StrComp(bkmk, bookmarklist(j), vbBinaryCompare)
           If matchflag = 0 Then
               Exit For
           End If
        Next
        If matchflag = 0 Then
           msg = "Bookmark of " & RecordKeyValue & vbCr & vbCr
           msg = msg & "Already Exists."
           MsgBox msg, , "myBookMarks()"
           Exit Function
        End If
        'Save Bookmark in Array
        ArrayIndex = ArrayIndex + 1
        If ArrayIndex > ArrayRange Then
          ArrayIndex = ArrayRange
          MsgBox "Boookmark List Full.", , "myBookMarks()"
          Exit Function
        End If
        bookmarklist(ArrayIndex) = bkmk
        
        GoSub FormatCombo
        
        ctrlCombo.RowSource = strRowSource
        ctrlCombo.Requery
    Case 2
        'Retrieve saved Bookmark and make the record current
        j = ctrlCombo.Value
        actvForm.Bookmark = bookmarklist(j)
    Case 3
        'Erase all Bookmarks from Array and
        'Delete the Combobox contents
        msg = "Erase Current Bookmark List...?"
        msgButton = vbYesNo + vbDefaultButton2 + vbQuestion
        If MsgBox(msg, msgButton, "myBookMarks()") = vbNo Then
            Exit Function
        End If
        For j = 1 To ArrayRange
           bookmarklist(j) = ""
        Next
        ctrlCombo.Value = Null
        ctrlCombo.RowSource = ""
        ArrayIndex = 0
    Case 4
        strSqltmp = "SELECT [Order Details].* "
        strSqltmp = strSqltmp & "FROM [Order Details] "
        strSqltmp = strSqltmp & "WHERE ((([OrderID]" & "&" & Chr$(34)
        strSqltmp = strSqltmp & "-" & Chr$(34) & "&" & "[ProductID]) In ('"
        
        strCriteria = ""
        For j = 0 To ArrayIndex - 1
            If Len(strCriteria) = 0 Then
                strCriteria = ctrlCombo.Column(1, j)
            Else
                strCriteria = strCriteria & "','" & ctrlCombo.Column(1, j)
            End If
        Next
        strCriteria = strCriteria & "')));"
        
        Set db = CurrentDb
        Set Qrydef = db.QueryDefs("OrderDetails_Bookmarks")
        strSql = strSqltmp & strCriteria
        Qrydef.SQL = strSql
        db.QueryDefs.Refresh
        DoCmd.OpenQuery "OrderDetails_Bookmarks", acViewNormal
End Select

myBookMarks_Exit:
Exit Function

FormatCombo:
'format current Bookmark serial number
'and OrderID to display in Combo Box
strRStmp = Chr$(34) & Format(ArrayIndex, "00") & Chr$(34) & ";"
strRStmp = strRStmp & Chr$(34) & RecordKeyValue & Chr$(34)

'get current combobox contents
strRowSource = ctrlCombo.RowSource

'Add the current Bookmark serial number
'and OrderID to the List in Combo Box
If Len(strRowSource) = 0 Then
     strRowSource = strRStmp
Else
     strRowSource = strRowSource & ";" & strRStmp
End If
Return

myBookMarks_Err:
MsgBox Err.Description, , "myBookMarks()"
Resume myBookMarks_Exit
End Function

Form

Command Button

First, Create a SELECT Query with the following SQL String and save it with the name OrderDetails_Bookmarks:


SELECT [Order Details].* FROM [Order Details];

Open the Form Order Details and create a Command Button next to the <<Reset Command Button as shown on the Form Design image given below:

Click on the Command Button to select it and display the Property Sheet (View- - > Properties)

Change the Name Property Value to cmdShow and the Caption Property Value to View Records.

Select the On Click Property, select EventProcedure from the drop down list and click on the Build (…) Button to open the Form's Code Module with the following empty skeleton of Sub-Routine:

Private Sub cmdShow_Click()

End Sub

Write the following line in the middle of the Sub-Routine as shown below:


Private Sub cmdShow_Click()
    myBookMarks 4, "cboBMList"
End Sub

Save and Close the Order Details Form and open it in Normal View.

Double-Click on the Record Selector of few records on the Form to add the Bookmark List in the Combo Box.

Click on the drop down control of the Combo Box to ensure that the selected Item Codes are added into the Combo Box List.

Click on the View Records Command Button to open the Query OrderDetails_Bookmarks in Datasheet View with the records that matches with the Combo Box Values.

Check the sample image of Query result overlapping the Form, displaying all the records that belong to the Combo Box List Values.

The Product Field displays Product Description rather than the Product Code that is appearing in the Bookmark Combo Box on the Main Form. The Display Width of the Combo Box in the Product Field is set to 0” to hide the Product Code in the Data View. But when you select an item from this Combo Box the Product Code is stored in the Order Details Table, because that is the Bound Column to the Table. When you double-click on the Record Selector the stored value of ProductID is taken rather than the Product Description, to combine with OrderID Value and updates the Combo Box List.

Want to find out how to open a Form with the last record that you were working on in the earlier session?, Click here?

Want to find out how to use Combo Boxes and List Boxes in different ways? Visit the following Links:

Selected ListBox Items and Dynamic Query

Create List from another ListBox

ListBox and Date : Part-1

ListBox and Date : Part-2

ComboBox Column Values

External Files List in Hyperlinks

Refresh Dependant ComboBox Contents

MS-Access Report and Page Total
Detail and Summary from Same Report
Hiding Report Lines Conditionally-3
Hiding Report Lines Conditionally-2
Hiding Report Lines Conditionally

Form Bookmarks and Data Editing

noreply@blogger.com (a.p.r. pillai) — Sun, 25 Oct 2009 17:31:00 +0000

You want to edit information on 25 records on the Form randomly. You will open the main data editing Form. Search for the record by entering the Key Value to find (say Employee Code or OrderID Value) in the Find (Ctrl+F) control and edit the record when found on the Form. This procedure is repeated for all 25 records for the first time because you don't have any other choice to find and edit the information.

But, the information you have changed is very critical and any mistakes in them may lead to serious issues. Mistakes can easily creep-in when you go through the finding and editing procedure in a hurry. It is important that you should have a second look at each record to verify and ensure the accuracy of changes.

Going through the same procedure to find all those 25 records again by displaying the Find control, keying in the Key Values and clicking on the Find button to reach the required record is not as enjoyable as it did for the first time.

But, if you can reach all those distant records one by one, in the same order of editing, without going through the above cumbersome procedure then it will be a great relief and can finish the work fast.

Why I said in the same order during editing because you are holding the source document of changes in the same order of your first visit to the records.

We will develop a trick with the Form's Bookmarks to make this kind of work easier for our Application Users.

FORM BOOKMARKS

When you open a Form attached to a Table, Query or SQL Statement each record on the Form is marked by MS-Access with a unique identifying tag known as Bookmark (a two Byte string Value). This is happening every time you open the Form with the above record sources. The Bookmarks are valid only on the current session of the Form and not stored in Tables.

We can read the Bookmark of any record from the Form's Bookmark Property, when the Record is Current on the Form, and store it in Variables in memory. Bookmarks saved this way can be used again to go back quickly to the same record we have visited earlier.

I have created a Function with the name myBookMarks() for this purpose and you can implement this method on any Form that has a Recordset attached to it by creating a Combo Box and a Command Button and four lines of Code in the VBA Code Module of the Form to run the Function.

You will definitely get a pat on your back from the User of your MS-Access Application for implementing this simple feature. So, let us start with our sample Project.

SAMPLE PROJECT

Open your VBA Editing Window (Alt+F11).

Create a new Standard Module (Insert - -> Module), Copy and Paste the following Code of myBookMarks() Function into the Module and Save it:



Option Compare Database
Option Explicit

Public Const ArrayRange As Integer = 25
Dim bookmarklist(1 To ArrayRange) As String, ArrayIndex As Integer

Public Function myBookMarks(ByVal ActionCode As Integer, ByVal cboBoxName As String, Optional ByVal RecordKeyValue) As String
'-----------------------------------------------------------------
'Author : a.p.r. pillai
'Date   : October-2009
'URL    : www.msaccesstips.com
'Remarks: All Rights Reserved by www.msaccesstips.com
'-----------------------------------------------------------------
'Action Code : 1 - Save Bookmark in Memory
'            : 2 - Retrieve Bookmark and make the record current
'            : 3 - Initialize Bookmark List and ComboBox contents
'-----------------------------------------------------------------
Dim ctrlCombo As ComboBox, actvForm As Form, bkmk As String
Dim j As Integer, msg As String, bkmkchk As Variant
Dim strRowSource As String, strRStmp As String, matchflag As Integer
Dim msgButton As Integer

On Error GoTo myBookMarks_Err

If ActionCode < 1 Or ActionCode > 3 Then
   msg = "Invalid Action Code : " & ActionCode & vbCr & vbCr
   msg = msg & "Valid Values : 1,2 or 3"
   MsgBox msg, , "myBookMarks()"
   Exit Function
End If

Set actvForm = Screen.ActiveForm
Set ctrlCombo = actvForm.Controls(cboBoxName)
Select Case ActionCode
    Case 1
        bkmk = actvForm.Bookmark
        'check for existence of same bookmark in Array
        matchflag = -1
        For j = 1 To ArrayIndex
           matchflag = StrComp(bkmk, bookmarklist(j), vbBinaryCompare)
           If matchflag = 0 Then
               Exit For
           End If
        Next
        If matchflag = 0 Then
           msg = "Bookmark of " & RecordKeyValue & vbCr & vbCr
           msg = msg & "Already Exists. "
           MsgBox msg, , "myBookMarks()"
           Exit Function
        End If
        'Save Bookmark in Array
        ArrayIndex = ArrayIndex + 1
        If ArrayIndex > ArrayRange Then
          ArrayIndex = ArrayRange
          MsgBox "Boookmark List Full. ", , "myBookMarks()"
          Exit Function
        End If
        bookmarklist(ArrayIndex) = bkmk
        
        GoSub FormatCombo
        
        ctrlCombo.RowSource = strRowSource
        ctrlCombo.Requery
    Case 2
        'Retrieve saved Bookmark and make the record current
        j = ctrlCombo.Value
        actvForm.Bookmark = bookmarklist(j)
    Case 3
        'Erase all Bookmarks from Array and
        'Delete the Combobox contents
        msg = "Erase Current Bookmark List...? "
        msgButton = vbYesNo + vbDefaultButton2 + vbQuestion
        If MsgBox(msg, msgButton, "myBookMarks()") = vbNo Then
            Exit Function
        End If
        For j = 1 To ArrayRange
           bookmarklist(j) = ""
        Next
        ctrlCombo.Value = Null
        ctrlCombo.RowSource = ""
        ArrayIndex = 0
End Select

myBookMarks_Exit:
Exit Function

FormatCombo:
'format current Bookmark serial number
'and OrderID to display in Combo Box
strRStmp = Chr$(34) & Format(ArrayIndex, "00") & Chr$(34) & ";"
strRStmp = strRStmp & Chr$(34) & RecordKeyValue & Chr$(34)

'get current combobox contents
strRowSource = ctrlCombo.RowSource

'Add the current Bookmark serial number
'and OrderID to the List in Combo Box
If Len(strRowSource) = 0 Then
     strRowSource = strRStmp
Else
     strRowSource = strRowSource & ";" & strRStmp
End If
Return

myBookMarks_Err:
MsgBox Err.Description, , "myBookMarks()"
Resume myBookMarks_Exit
End Function

Import the following Tables from C:\Program Files\Microsoft Office\Office11\Samples\Northwind.mdb sample Database:

Order Details

Products

NB:

Order Details

Click on the Order Details Table to select it.

Select Form from Insert Menu and select AutoForm : Tabular from the displayed list.

MS-Access creates a Tabular Form quickly. Save the Form with the name Order Details.

Open Order Details Form in Design View.

Expand the Form Header area and move the Field Headings down for enough space to create a Combo Box and a Command Button as shown on the sample design above.

Display the ToolBox (View - ->ToolBox), if it is not already visible.

If the Control Wizards Tool Button is already in selected state then click on it to de-select it.

Select the Combo Box Tool from the ToolBox and draw a Combo Box in the Header Section of the Form as shown on the design above.

While the Combo Box is still in selected state; select Properties from View menu to display the Property Sheet of the Combo Box.

Change the following Property Values as shown below:

Name = cboBMList

Row Source Type = Value List

Column Count = 2

Column Widths = .5";1"

Bound Column = 1

List Rows = 8

List Width = 1.5"

Change the Caption of the Child Label, attached to the Combo Box, to Bookmark List: .

Create a Command Button to the right side of the Combo Box.

Display the Property Sheet of the Command Button.

Change the following Property Values as shown Below:

Name = cmdReset

Caption = << Reset

Display the Code Module of the Form (View - -> Code).

Copy and Paste the following VBA Code into the Module; Save and Close the Form:



Option Compare Database

Private Sub Form_DblClick(Cancel As Integer)
    'Save Current Record's Bookmark in memory
    myBookMarks 1, "cboBMList", Me![OrderID]
End Sub

Private Sub cboBMList_Click()
    'Retrieve the bookmark using the
    'index number from the Combobox List
    'and make the respective record current
    myBookMarks 2, "cboBMList"
End Sub

Private Sub cmdReset_Click()
    'Initialize Bookmarks and Combobox contents
    myBookMarks 3, "cboBMList"
End Sub

Private Sub Form_Unload(Cancel As Integer)
    'Remove all Bookmarks from Memory
    myBookMarks 3, "cboBMList"
End Sub

Open the Order Details Form in Normal View.

Double-Click on one of the record-selectors at the left side of the Form.

Click on the Combo Box Drop-down control to check whether the OrderID value of the Record that you have double-clicked is added into the Combo Box List with a sequence number in the first Column or not.

Make few more double-click on different Record selectors up or down on the form as you like.

Check the Combo Box contents again to ensure that all these record references are added into the Combo Box with running serial numbers.

Click on the drop-down control of the Combo Box to display the list of Bookmarks and click on one of the item from the list.

OrderId

Find

OrderID

BookMarkList

myBookMarks()

Public Const ArrayRange As Integer = 25
Dim bookmarklist(1 To ArrayRange) As String, ArrayIndex As Integer

Scroll down the vertical scrollbar of the Form and double-click on the Record-Selectors of few more records from distant area of the Recordset.

Now, try to reach any of these Bookmarks we have added into the list by selecting them one by one from the Combo Box List.

If you want to erase all those Bookmarks from the BookmarkList Array in memory click on the << Reset Command Button. After this, you can create a fresh list of Bookmarks.

The OrderID Field Value added to the Combo Box along with the Index Number of the Bookmark Array can be used to cross check with the retrieved record value to ensure correctness.

Let us look the Sub-Routines we have copied into the Form Module and check what they are doing.

Private Sub Form_DblClick(Cancel As Integer)
myBookMarks 1, "cboBMList", Me![OrderID]
End Sub

When you double-click on the Record Selector of a record the above Sub-Routine calls the main Function myBookmarks() with the following parameters:

Action Code : 1 - indicates to fetch the Current Bookmark (a two byte string value consists of displayable/non-displayable characters) from the Active Form and save it in Memory in BookMarkList Array after incrementing the Array index number in Variable ArrayIndex. The Action Code is tested in the Select Case….End Select segment in the myBookMarks() Function. The Bookmark value itself is not displayed anywhere.

Combo Box Name : "cboBMList" – to display the Index Number of the BookmarkList Array in the Combo Box. The Name of the Control is enough to reference it on the Active Form.

Record Field Value : OrderID – to display the Record Field Value in the Combo Box along with the BookMarkList Array Index number. You can use any Field Value of your Table so far as it serves the purpose of checking the correctness of the record retrieved using the Bookmark.

The third parameter of myBookMarks() Function is defined as Optional and is omitted while calling the Functions to retrieve the Bookmark or to erase the Bookmarks List in the following three Sub-Routines respectively:

Private Sub cboBMList_Click()
myBookMarks 2, "cboBMList"
End Sub

Private Sub cmdReset_Click()
myBookMarks 3, "cboBMList"
End Sub

‘Erases the Bookmarks when the Form is closed
Private Sub Form_Unload(Cancel As Integer)
'Remove all Bookmarks from Memory
myBookMarks 3, "cboBMList"
End Sub

Since, the main Function myBookMarks() references the Active Form you can implement this method on any Form without directly passing any Form Name to the Function.

NB:

Saving, retrieving and using Bookmarks for finding records is valid only for the current session of the Form.

Re-querying the Form's contents (not Refreshing) re-creates the Bookmarks for the Recordset on the form and earlier saved Bookmarks may not be valid after that. You must create fresh Bookmark List to use correctly.

This method will not work on Forms attached to external Data Sources, linked to Microsoft Access, that doesn't support bookmarks.

Detail and Summary from Same Report
Hiding Report Lines Conditionally-3
Hiding Report Lines Conditionally-2
Hiding Report Lines Conditionally
Network and Report Page Setup-3

Run Slide Show when Form is Idle

noreply@blogger.com (a.p.r. pillai) — Fri, 16 Oct 2009 06:34:00 +0000

Dear Readers,

I am very sorry about last two weeks unexpected events and could not come out with the weekly Articles. I had to go to India on an emergency on 27th September 2009 and the Website also failed on the same day itself due to some errors in the Web Server Configuration changes made by Administrators.

I have noticed this serious state of the Website on 8th of October and could bring up the Site only on 9th of October 2009. I deeply regret the inconvenience caused to you.

This week, we will create a Slide Show of images on a Form that runs when the Form remains idle for a certain period of time. It works something like the following:

When the Main Switchboard Form remains idle for about one minute the Slide Show runs and each image will change on a fixed interval of about 6 Seconds. The Idle Time and Interval Time can be changed according to your specific needs.

The idle time of the Form is calculated based on the inactivity (i.e. no interaction with the User) of the Main Switchboard Form and the active control on the Form remains active for more than one minute.

If you click on a Command Button or List box or any other control other than the active control on the Main Switchboard Form then the Form comes out of idle state and the Slide Show stops.

Checking for the idle state of the Form starts again from that point onwards with the new active control. If the same control remains active for more than one minute then the slide show starts again.

If you open another Form over the Main Switchboard Form then the slide show sleeps until the Main Switchboard From becomes active again.

You need few Bitmap Images of Landscapes or Photos and you can use as many images as you like for the Slide Show. All the images should have the same name with a Sequence Number at the end like Image1.bmp, Image2.bmp, Image3.bmp and so on. You can use .jpg or .GIF and other images but this will display a progress bar for a brief moment while loading the image into the Image Control. All images must be of the same type.

A sample Main Switchboard Form with the active Slide Show is given below:

To try out this interesting trick; first organize few Bitmap Images into a folder as explained above.

Make a copy of your existing Main Switchboard Form (Control Screen).

Open the Form in Design View.

Make enough room on the Form to create an Image Control on the Form.

Display the Toolbox (View - ->Toolbox), if it is not visible.

Select Control Wizards button on the Toolbox to make it active.

Select Image control Tool from the Toolbox and draw an Image Control on the Form where you want the Slide Show to appear.

The Common Dialog Control will display. Browse to the Images location and select the image with Serial Number 1 (Image1.bmp).

While the Image control is still in selected state; display the Property Sheet (View - -> Properties) and change the following Property Values as indicated below:

Name = ImageFrame

Size Mode = Zoom

NB:

Picture

Display the Code Module of the Form (View - -> Code).

Press Ctrl+A to highlight the existing VBA Code in the Module, if present, and press Delete to remove them.

Copy and Paste the following Code into the Form Module.


Option Compare Database
Option Explicit

Dim actForm As String, actControl As String, idletime As Integer
Dim oldForm As String, oldControl As String, imageNo As Integer

Private Sub Form_Activate()
    Me.TimerInterval = 1000
End Sub

Private Sub Form_Deactivate()
    Me.TimerInterval = 0
    Me.ImageFrame.Visible = False
End Sub

Private Sub Form_Load()
DoCmd.Restore

idletime = 0
Me.ImageFrame.Visible = False
Me.TimerInterval = 1000

End Sub

Private Sub Form_Timer()

actForm = Screen.activeForm.Name
actControl = Screen.activeForm.activeControl.Name

If actForm = oldForm And actControl = oldControl And actForm = "Control" Then
    idletime = idletime + 1
Else
    oldForm = actForm
    oldControl = actControl
    idletime = 0
    Me.ImageFrame.Visible = False
    DoEvents
End If

If idletime > 60 Then
   If idletime Mod 6 = 0 Then
        Me.ImageFrame.Visible = True
        imageNo = imageNo + 1
        imageNo = IIf(imageNo < 1 Or imageNo > 9, 1, imageNo)
        Me.ImageFrame.Picture = "E:\D\Movie\Britanica_Scenes\scene" & imageNo & ".bmp"
        DoEvents
   End If
End If

End Sub

Change the word "Control" in the first line (with bold letters) with your own Main Switchboard Form Name.

Change Number 9, in the second line with bold letters, to match with the number of Images you have saved for the Slide Show as explained above.

Copy the Image Location Address and Image Name except Serial Number from the image location address we have saved in Notepad Document and Paste over the text E:\D\Movie\Britanica_Scenes\scene in the Program.

If your pictures are not Bitmap Images then change the file extension ".bmp" to indicate your image type.

Save and Close the Form.

Open the Main Switchboard Form in Normal View.

Wait for one minute to begin the Slide Show.

When the Slide Show is running, if you click on a Control other than the active control on the Form the Slide Show will stop and the image will disappear.

If you don't click on any other control on the Form and the time elapsed is more than one minute, since your last click on a Control, the Slide Show will run again.

If you want to increase or decrease the idle time of the Form then change the value in the VBA line If idletime > 60 Then to an appropriate value you prefer.

Each Image stays displayed for about 6 seconds. If you want to increase or decrease the display time then change the Value in the VBA line If idletime Mod 6 = 0 Then to the required value you prefer.

Filter Function Output In Listbox-2

noreply@blogger.com (a.p.r. pillai) — Fri, 25 Sep 2009 12:01:00 +0000

Last week we have seen the usage of Filter() Function with a simple example and I hope you understood how it works. We have assigned constant values to the Source Array elements directly to keep the VBA Code as simple as possible.

We can filter data on Forms by setting Criteria on the Filter Property of Forms. Similarly, we can use conditions in Queries to filter information from Tables as well.

But, the Filter() Function gives a unique way of filtering data from an Array of information loaded from Tables or Queries and create output quickly based on matching or non-matching options.

Let us try out the Filter() Function in an Address Book Application to quickly find persons or places that matches with the specified search text and display them in a List Box. We will use Names and Addresses from the Employees Table of Northwind.mdb sample database for our experiment.

Following is the User Interface design that we planned to create and explains how the User will interact with it to display information quickly on the Form.

We will design a Form with a List Box, a Text Box Control, a Check-Box Control and a Command Button for our experiment. An image of such a Form in Design View is given below:

When the Form is open in normal view the List Box and Text Box Controls will be empty. The User can enter the word ALL in the Text Box Control and click the Command Button to display the Name and Addresses of all Employees in the List Box.

Or

The User can enter a word or phrase, like part of a Name or Address, that can match anywhere within the Name and Address text, and click on the Command Button to filter out the matching items and to display them in the List Box.

If the Matching Cases Check-Box is in selected state then the Filter action will select records that matches with the search text given in the Text Box Control otherwise it will select all records that do not match with the search text.

To provide the User with the above facility we need two Subroutines on the Form's Code Module and a User Defined Function in Standard Module of the Database to use the Filter() Function.

When the User opens the above Form the first Sub-Routine is run from the Form_Load() EventProcedure to read the data (First Name, Last Name & Address) from Employees Table, join all the three field values into a single row of text and load them into a Singly Dimensioned Array Variable in Memory. This data will remain in memory till the User closes the Form.

The second Sub-Routine is run when the User clicks on the Command Button to extract information from the Source Array with the help of Filter() function, based on the search text entered into the Text Box Control.

The Filter() Function will extract the entries that matches with the search Text in the Text Box Control, from the Source Array Variable, and save the output into the target variable xTarget. All we have to do is to take these values, format and insert as Row Source Property Value to display them in the List Box.

Let us prepare for the Address Book's Quick Find Project.

Import Employees Table from C:\Program Files\Microsoft Office\Office11\Samples\Northwind.mdb sample database.

Open a new Form in Design View.

Select the List Box Control from the Tool Box and draw a List Box as shown on the design above.

While the List Box is in selected state display the Property Sheet (View - - > Properties) and change the following Property Values as given below:

Name = AddBook

Row Source Type = Value List

Width = 4.5"

Height = 1.75"

Font Name = Courier New

Font Size = 10

Position the Child Label attached to the List Box above and change the Caption value to Address Book.

Draw a Text Box below the List Box. Change the Name Property of the Text Box to xFind. Position the Child Label above the Text Box and change the Caption value to Search Text/ALL.

Create a Check-Box Control to the right of the Text Box. Change the Name Property of the Check-Box to MatchFlag. Change the Default Value Property to True. Change the Caption value of the child label to Matching Cases.

Create a Command Button to the right of the Check-Box control. Change the Name Property Value of the Command Button to cmdFilter and the Caption Property Value to Filter.

Name

Display the Code Module of the Form (View- - >Code).

Copy and paste the following Code into the Form Module:


Option Compare Database
Option Explicit
Dim xSource() As Variant

Private Sub Form_Load()
Dim db As Database, rst As Recordset, J As Integer
Dim FName As String * 12, LName As String * 12, Add As String * 20

'Take the count of records
J = DCount("*", "Employees")

'redimension the array for number of records
ReDim xSource(J) As Variant

Set db = CurrentDb
Set rst = db.OpenRecordset("Employees", dbOpenDynaset)
'load the name and addresses into the array
J = 0
Do Until rst.EOF
   FName = rst![FirstName]
   LName = rst![LastName]
   Add = rst![Address]
  xSource(J) = FName & LName & Add
rst.MoveNext
J = J + 1
Loop
rst.Close
Set rst = Nothing
Set db = Nothing
End Sub


Private Sub cmdFilter_Click()
Dim x_Find As String, xlist As String, xTarget As Variant
Dim x_MatchFlag As Boolean, J As Integer

Me.Refresh
x_Find = Nz(Me![xFind], "")
x_MatchFlag = Nz(Me![MatchFlag], 0)

'if no search criteria then exit
If Len(x_Find) = 0 Then
  Exit Sub
End If
    'initialize list box
    xlist = ""
    Me.AddBook.RowSource = xlist
    Me.AddBook.Requery

If UCase(x_Find) = "ALL" Then
    'Take all values from the Source Array
    'Format it as listbox items
    For J = 0 To UBound(xSource())
      xlist = xlist & xSource(J) & ";"
    Next
Else
    'Call the Filter Function
    xTarget = GetFiltered(xSource(), x_Find, x_MatchFlag)
    'format the returned values as list box items
    If Len(xTarget(0)) > 0 Then
        For J = 0 To UBound(xTarget)
            xlist = xlist & xTarget(J) & ";"
        Next
    End If
End If
    'remove the semicolon from
    'the end of the list box Value List
    If Len(xlist) > 0 Then
        xlist = Left(xlist, Len(xlist) - 1)
    End If
    'insert the list item string
    'and refresh the list box
    Me.AddBook.RowSource = xlist
    Me.AddBook.Requery

End Sub

Save the Form with the name Filter Form.

Copy and paste the following Function in a Standard Module and save the Module:


Public Function GetFiltered(ByRef SourceArray() As Variant, ByVal xFilterText As Variant, ByVal FilterType As Boolean) As Variant

GetFiltered = Filter(SourceArray, xFilterText, FilterType)

End Function

Filter()

Filter

Filter()

GetFiltered()

By Reference

Open the Filter Form in normal View.

Enter the word ALL (in this case the Matching Cases flag has no effect) in the Text Box control and Click on the Filter Command Button.

xSource()

Enter the text Ave in the Text Box and see that the Matching Cases check box is in selected state.

Click on the Command Button.

Ave

Remove the check-mark from the Matching Cases check box and click on the Filter Command Button again.

Now, all items except the lines with the word Ave are listed in the List Box.

If you go through the Programs that we have copied into the Form Module you can see that we have declared the xSource() Array Variable in the Global area of the Module so that we can use the data in both Sub-Routines in the Form Module.

In the Form_Load() Event Procedure we have declared three Variables as fixed length String Type (see the declaration line given below).

Dim FName As String * 12, LName As String * 12, Add As String * 20

When we read employee Name and Address into these Variables the values will be left justified inside the Variable and balance area of the declared size will be space filled to the right. This method will space out items in fixed distance from each other and properly aligned when displayed.

It is important that we use a Fixed Width Font, like Courier New, for the List Box display and we set this in Step-4 above.

If you click the Filter Command Button when the Text Box is empty then the program terminates, otherwise it calls the GetFiltered() Function by passing the parameter values.

The output Values are returned in the xTarget Array and the next steps formats the Value List and displays them in the List Box.

Hiding Report Lines Conditionally-3
Hiding Report Lines Conditionally-2
Hiding Report Lines Conditionally
Network and Report Page Setup-3
Network and Report Page Setup-2

Filter Function output in ListBox

noreply@blogger.com (a.p.r. pillai) — Fri, 18 Sep 2009 13:45:00 +0000

This FILTER is not related to a Query or WHERE clause in SQL or Filter settings on a Form. It is a built-in Function. Its usage is very interesting and it is useful to quickly filter out data from an Array of information through text matching. We will use this Function to search for values across more than one field of data from a Table, extract matched items or mismatch items, as the case may be, and display them in a List Box.

But first, let us look into a simple example to understand its usage. Copy and Paste the sample VBA code given below into a Standard Module in your database:


Public Function myFilter()
Dim X(7) As Variant, Y As Variant
Dim J as Integer, msg as String

X(0) = "Strawberry Milk"
X(1) = "Chocolates"
X(2) = "Milkshake"
X(3) = "Mango Juice"
X(4) = "Icecold Milk"
X(5) = "Apple Juice"
X(6) = "Buttermilk"
X(7) = "Vanilla Icecream"

'Extract all items containing the text "milk" from Array X()
'and save the output in Array Y()

Y = FILTER(x, "milk", True, vbTextCompare)

msg = ""
For J = 0 To UBound(Y)
   msg = msg & J + 1 & ". " & Y(J) & vbCr
Next

MsgBox msg

End Function

Click anywhere within the Code and press F5 to Run the Code. The output of the function will be displayed in an MsgBox.

Let us examine the above code closely. The Variable X is dimensioned for eight elements and loaded the Array with text values.

The FILTER() Function in the statement Y = FILTER(X,"milk",True,vbTextCompare) extracts the items that matches with the search text milk from the Source Array of values from Variable X and saves the output as an array of Values into Variable Y.

The FILTER() Function accepts four parameters.

The first parameter X is the Array containing the Text Values.

The second parameter value milk is the search text that is compared with each item of the Array of values in variable X and if a match found anywhere within the Array Item then extracts that item as output and adds it into an element of the target Array Variable Y.

The third parameter value True asks the Filter Function to extract the matched items as output and save them in Variable Y. When this value is set as False then the output will be items that do not contain the search text milk.

The fourth Parameter asks the Filter Function to apply a specific comparison method like Binary Comparison, Database Comparison or Text Comparison method. Here, we have used Text Comparison method. Third and fourth parameters are Optional.

You may try the above Code with different piece of search text, like juice or Ice etc.

If you look at the Variable declarations of the Code you can see that we have declared the Variable Y as a simple Variant Type and not as an Array Variable.

But, this declaration is changed by the FILTER() Function and re-dimensions it as an Array automatically, depending on the output of the filter action. Every time when we run the code with different search text parameter this can be different and unpredictable too. So, we have used the UBound() Function to find the number of elements in the output Array for the For…Next loop to take all the items and format a string to display the output items in the MsgBox.

The Source Variable must be a singly dimensioned Array. If your search text needs to be compared with several piece of information then join all of them together as a single string and load into the singly dimensioned array.

The Filter() Function will not work in Code Modules of Form or Report.

I have developed an Application around this Function for our Secretary to find all the Office Files with their location addresses (we have hundreds of them) that matches a specific word or phrase in their Subject or Description Fields and display them in a List Box on a Form.

We will try a similar and simple example with data taken from more than one field of the Employees Table, joined together as source Array contents and display the Filter result in a List Box. I will give details of this example in the next Article.

Till that time if you find you can use this function for some of your own tasks, you may do that. When I come out with my example you can compare yours with that and find the difference.

If you did it differently share your ideas with me, so that I can learn something from you too.

Hiding Report Lines Conditionally-2
Hiding Report Lines Conditionally
Network and Report Page Setup-3
Network and Report Page Setup-2
Network and Report Page Setup

Dynamic ListBox ComboBox Contents

noreply@blogger.com (a.p.r. pillai) — Fri, 11 Sep 2009 16:10:00 +0000

How about displaying different Set of un-related Values in a List Box; Values in different column layouts interchangeably? Perhaps, the change over can be with the click of a Button or based on some other action from the User.

When we create a List Box or Combo Box we are provided with three different options in MS-Access:Table/Query, Value List or Field List to choose from in the Row Source Type Property to fill with values in them. We normally use one of these Options to create a Combo Box or List Box and insert other Property Values, like Column Count, Column Widths, Bound Column etc. manually.

But, we can use a User Defined Function in the Row Source Type Property besides the values mentioned above to fill with Values in a List Box or Combo Box.

Even though this Function is known as a User Defined Function it is actually defined by Microsoft Access and given in the Help Documents with specific rules as how to use it with various parameter Values and VBA Code structure. All we have to do is to Copy this Code and Customize to our specific needs.

You can get the details of this Function, by placing the insertion point in the Row Source Type Property of a List Box or Combo Box Control and by pressing F1 Key to display the Help Document. When the Help Document is open look for the Hyperlink with the description User-define Function and click on it to display the details of various parameters and what they do in the Function.

We will look closely at the second example Code given in the Help Document. The VBA Code is given below and we will use it in a List Box to get a general idea of its usage.


Function ListMDBs(fld As Control, ID As Variant,  row As Variant, col As Variant,  code As Variant) As Variant
    Static dbs(127) As String, Entries As Integer
    Dim ReturnVal As Variant
    ReturnVal = Null
    Select Case code
        Case acLBInitialize                ' Initialize.
            Entries = 0
            dbs(Entries) = Dir("*.MDB")
            Do Until dbs(Entries) = "" Or Entries >= 127
                Entries = Entries + 1
                dbs(Entries) = Dir
            Loop
            ReturnVal = Entries
        Case acLBOpen                        ' Open.
            ' Generate unique ID for control.
            ReturnVal = Timer
        Case acLBGetRowCount            ' Get number of rows.
            ReturnVal = Entries
        Case acLBGetColumnCount    ' Get number of columns.
            ReturnVal = 1
        Case acLBGetColumnWidth    ' Column width.
            ' -1 forces use of default width.
            ReturnVal = -1
        Case acLBGetValue                    ' Get data.
            ReturnVal = dbs(row)
        Case acLBEnd                        ' End.
            Erase dbs
    End Select
    ListMDBs = ReturnVal
End Function

Copy the above Code into a new Standard Module in your Database and save it.

Open a new Form in Design View and create a List Box on it.

Click on the List Box to select it, if it is not already in selected state.

Display the Property Sheet (View - -> Properties).

Insert the Function name ListMDBs in the Row Source Type Property overwriting the value Table/Query.

Save the Form.

Open the Form in normal view.

A list of databases from your default directory (check Tools - -> Options - -> General Tab for your default directory location) will appear in the List Box. A sample image of a ListBox is given below:

You may modify the following entry in the Program to take listing of Word or Excel files in the List Box from different Folder like:

dbs(Entries) = Dir("*.xls")

OR

dbs(Entries) = Dir("C:\My Documents\*.xls")

The dbs(Entries) = Dir in the subsequent calls uses the first call parameter value "C:\My Documents\*.xls" by default and populates the String Array dbs() in the Initialize step of the Program.

This is one of the segments of the Code we can customize and use it for different requirements. After the initializing phase the Function is called repeatedly to obtain other values likes Rows Count, Column Count and others to define the Property Values of the List Box, which we normally set manually on the List Box in design time.

The ColumnWidths, when set with the Value -1 in the Program gives the signal to use the Default Values set manually on the Property Sheet without change. This is useful when we need a mixed format of different column sizes when more than one column of information is displayed.

Finally, the following statements pass the List Box Source Values dbs(row) that we have created under the Initialize stage for displaying in the List Box:

Case acLBGetValue ' Get data.
ReturnVal = dbs(row)

The row holds the value for the actual number of items we have loaded into the dbs() Array of 127 elements declared initially. This value is passed to the Function through the Entries Variable in the following segment of the Code:

Case acLBGetRowCount ' Get number of rows.
ReturnVal = Entries

The dbs Variable is declared as a Static Singly Dimensioned Array with 128 elements (0 to 127) to retain the value loaded into it in the Initialize stage when the User Defined Function ListMDBs is called repeatedly by MS-Access. The Parameter Values are automatically passed by MS-Access and we don’t need to provide them explicitly. The first Parameter is the name of the List Box Control. The second Parameter ID is essential and this is set with the System Timer under the following statements:

Case acLBOpen ' Open.
' Generate unique ID for control.
ReturnVal = Timer

The System Timer generates new values at every millisecond interval and this ensures that a unique number will always assign to this parameter as a unique Identification Value if more than one User Defined Function is active at the same time.

The Code parameter passes appropriate values used in the Select Case statements and uses the Returned Values to define the List Box Property Values.

If you understood or have a general idea as how this function works to define the contents of a List Box or Combo Box then we can go forward with the trick that I have mentioned at the beginning of this Article.

We will create a Copy of the above Code and modify to create a List Box with Employees Code and First Name Values (two Columns of Values) from the Employees Table of Northwind.mdb database.

Import the Employees Table from C:\Program Files\Microsoft Office\Office11\Samples\Northwind.mdb.

Copy the following VBA Code into the Standard Module of your database and save the Module:


Function ListBoxValues(fld As Control, ID As Variant, row As Variant, col As Variant,
     code As Variant) As Variant
    Static xList(127, 0 To 1) As String, Entries As Integer
    Dim ReturnVal As Variant, k As Integer
    Dim db As Database, rst As Recordset, recCount As Integer
    
    ReturnVal = Null
    Select Case code
        Case acLBInitialize  ' Initialize.
            Set db = CurrentDb
            Set rst = db.OpenRecordset("Employees", dbOpenDynaset)
            Entries = 0
            Do Until rst.EOF
               For k = 0 To 1
                    xList(Entries, k) = rst.Fields(k).Value
               Next
               rst.MoveNext
               Entries = Entries + 1
            Loop
            rst.Close
            ReturnVal = Entries
        Case acLBOpen                    ' Open.
            ' Generate unique ID for control.
            ReturnVal = Timer
        Case acLBGetRowCount         ' Get number of rows.
            ReturnVal = Entries
        Case acLBGetColumnCount    ' Get number of columns.
            ReturnVal = 2
        Case acLBGetColumnWidth    ' Column width.
            ' -1 forces use of default width.
            ReturnVal = -1
        Case acLBGetValue                ' Get data.
            ReturnVal = xList(row, col)
        Case acLBEnd                        ' End.
            Erase xList
    End Select
    ListBoxValues = ReturnVal
End Function

Open the Form in Design View with the List Box that we have created earlier.

Click on the List Box to select it.

Display the Property Sheet (View- ->Properties).

Change the Column Widths Property Value to 0.5";1.5".

The following lines of Code say that use the values set in the Column Widths Property without change:

Case acLBGetColumnWidth ' Column width.
' -1 forces use of default width.
ReturnVal = -1

If the value in the Column Widths Property is a single value (say 1") then a multi-column List will use 1 Inch for all Columns. This may not give a nice look for values with different length. You may try this with different values to understand them better.
Create a Command Button on the Form.
Ensure that the Command Button is in selected state and display the Property Sheet.

Click on the On Click Property and select [EventProcedure] from the Drop Down control and Click on the Build (…) Button to open the VBA Module with the skeleton of the On Click Event Procedure.

Copy and Paste the following lines of Code in the middle of the Event Procedure.


Me.List40.RowSourceType = "ListMDBs"
Me.List40.Requery

Change the name of the List Box (the name in Bold Letters) to match with the name of your own List Box.

Create another Command Button below the first one.

Repeat the Procedure in Step-10 and 11 for the On Click Property of the second Command Button.

Copy and Paste the following Code in the middle of the On Click Event Procedure:


Me.List40.RowSourceType = "ListBoxValues"
Me.List40.Requery

Change the name of the List Box (the name in Bold Letters) in the Code to match with the name of your own List Box.

Save and Close the Form.

Open the Form in Normal View.

ListMDBs

Row Source Type

Click on the second Command Button to change the List Box contents to the Employees List.

Click on the first Command Button to change the List Box Contents back to the Database List again.

It works for Combo Boxes in the same way. You may create a Combo Box control and try in the same value.

Don't forget to set the Default Value Property with the value 1, otherwise the Combo Box may not show anything in its Text Box area before you select an item from the List.

Hiding Report Lines Conditionally
Network and Report Page Setup-3
Network and Report Page Setup-2
Network and Report Page Setup
Filter by Character and Sort

Office Assistant And Msgbox Menus-3

noreply@blogger.com (a.p.r. pillai) — Fri, 04 Sep 2009 13:55:00 +0000

After going through the earlier Articles on this subject I hope that the Readers are now familiar with programming the Balloon Object of Microsoft Office Assistant. You have seen that you can use this feature with few lines of customizable VBA Code to display MsgBox text formatted with Color, underline and with your favorite Images on them. We can display Menus on them to obtain responses from Users, besides the buttons that we normally use like OK, Cancel, Yes, No etc.

Since, this Article is the third part of this series I suggest that new Readers may go through the earlier Documents on this subject to learn interesting and simple ways to use this feature in MS-Access before continuing with this Article. Links to those Articles are given below:

Color and Picture in MsgBox

Office Assistant and MsgBox Menus

Office Assistant and MsgBox Menus-2

Last week we have learned how to display Clickable Menu Options in Message Box with the use of Office Assistant. The Image of that example is given below.

We have displayed the Menu Options on Message Box with the Labels Property of the Balloon Object of Office Assistant.

Here, we will learn how to display Menu Options with Checkboxes and how responses from the User can be obtained, examined and execute actions that is programmed for each choice made? The example Code and the sample image of MsgBox that displays the Check-Box Menu are given below:


Public Function ChoicesCheckBox()
Dim i As Long, msg As String
Dim bln As Balloon, j As Integer
Dim selected As Integer, checked As Integer

Set bln = Assistant.NewBalloon
With bln
    .Heading = "Select Data Output Option"
    .Checkboxes(1).text = "Print Preview."
    .Checkboxes(2).text = "Export to Excel."
    .Checkboxes(3).text = "Datasheet View."
    .Button = msoButtonSetOkCancel
    .text = "Select one of " _
       & .Checkboxes.Count & " Choices?"
    i = .Show
    
    selected = 0
    If i = msoBalloonButtonOK Then
        'Validate Selection
        For j = 1 To 3
            If .Checkboxes(j).checked = True Then
                selected = selected + 1
                checked = j
            End If
        Next

        'If User selected more than one item
        'then re-run this program and force the
        'User to select only one item as suggested
        ‘in the message text.
        If selected = 0 or selected > 1 Then
           Call ChoicesCheckBox
        Else
            Select Case checked
                Case 1
                    Debug.Print .Checkboxes(checked).text
                Case 2
                    Debug.Print .Checkboxes(checked).text
                Case 3
                   Debug.Print .Checkboxes(checked).text
            End Select
        End If
    End If
End With

End Function

Like the Labels Property Array the dimension of CheckBoxes also can be up to a maximum of five elements only.

In our earlier example we have not used the OK or Cancel buttons along with the Labels based Menu because the Balloon Button (msoBalloonTypeButtons) based options were clickable and accepts the clicked item as a valid response and dismisses the Office Assistant on this action. The clicked item's index number is returned as the response value and it was easy to check this value and execute the action accordingly.

But in the case of Check-Boxes this is little more complex because of the following reasons

The Check Boxes can be either in checked or in unchecked state, which needs to be validated.

The User may put check-marks on one or more Options at the same time. If this cannot be allowed then there must be a validation check and force the User to make selection of one item only.

If the User has the option of selecting more than one item then program must be written to execute more than one action based on the combination of selections made.

In either case we have to inspect the checked or un-checked state of each element of the CheckBoxes Array to determine the validity of Menu selection.

In the example code given above the User can select only one item at a time.

In the validation check stage of the code, first we are checking whether the User has clicked the OK Button or not.

If she did then in the next step we take a count of all check-marked items, in the Variable selected.

If the value in Variable selected is zero (User clicked OK Button without selecting any option from the list) or selected more than one item then the Program is called again from within the ChoicesCheckBox() Function itself. This will refresh the Menu, removes the check marks and display it again. This will force the User to make only one selection as suggested in the message or she can click Cancel Button.

In the next step the action is programmed based on the selection made by the User.

If the User is allowed to put check-marks on more than one item (depending on the purpose of the Message Box based Menu) then the validation check and the execution of actions can be different and the code must be written accordingly.

The methods which I have introduced to you and explained in these three Articles are good to learn the basics of this feature and easy to understand the usage of different Properties of Balloon Object of Office Assistant.

But, you will appreciate the fact that duplicating and customizing these Codes everywhere in your Programs for different needs is not advisable. This will increase the size of your database, no flexibility in usage of Code and it is not good programming practice either.

You may go through the Articles (links given below) published earlier on this Subject that shows how to define Public Functions like MsgOK(), MsgYN(), MsgOKCL() and others with the use of Office Assistant. It simplifies the usage of this feature, without duplicating the Code, and can use them freely anywhere in your Programs like MS-Access MsgBox() Function.

The above Function Names themselves suggests what kind of Buttons will appear in the Message Box when they are called with the minimum Parameter Value of Message Text alone or Message Text and Title Values.

Message Box with Office Assistant

Message Box with Options Menu

Office Assistant with CheckBox Menu

A comparison of the above User Defined Function usage with the MsgBox is given below for references. The underscore character in the text indicates the continuation of lines and should not be used when all values are placed on the same line.

MS-Access MsgBox() usage	Office Assistant based User Defined Function usage
MsgBox "Welcome to Tips and Tricks"	MsgOK "Welcome to Tips and Tricks"
X = MsgBox("Shut Down Application", _ vbQuestion+vbDefaultButton2+vbYesNo, _ "cmdClose_Click()")	X = MsgYN("Shut Down Application", _ "cmdClose_Click()")
X = MsgBox( "Click OK to Proceed or Cancel?", _ vbOKCancel+vbDefaultButton2+vbQuestion, _ "MonthEndProcess()")	X = MsgOKCL("Click OK to Proceed or Cancel?", _ "MonthEndProcess()")

Network and Report Page Setup-3
Network and Report Page Setup-2
Network and Report Page Setup
Filter by Character and Sort
Animating Label on Search Success

Office Assistant And Msgbox Menus-2

noreply@blogger.com (a.p.r. pillai) — Fri, 28 Aug 2009 07:32:00 +0000

This is the continuation of last Week's Article: Office Assistant and MsgBox Menus. Readers may go through that Page first, if you have not already done so, before continuing.

Last week we have learned how to use Office Assistant for MsgBox in a simple way and seen how to create a Menu and present it to the User, with the Labels Property of the Balloon Object.

We have seen that we can display the Menu from Labels().Text Property in three different ways by setting the Values of BalloonType Property:

BalloonType = msoBalloonTypeButtons

Buttons

BalloonType = msoBalloonTypeBullets

BalloonType = msoBalloonTypeNumbers

The second and third BalloonType Values displays the Labels().Text in different styles but they cannot be selected by the User. So, we can use these options for different situations in Programs.

Let us look little closer to the overall behavior of the Balloon Object when you display MsgBox with Office Assistant, to understand it better.

If you go back and try those earlier examples, you can see that while a MsgBox with the Office Assistant's Balloon Object is displayed you cannot click or work with any other object in the database unless you dismiss the Balloon by responding to the actions you are suggested to do, like clicking on the OK or Cancel Button and so on. This is true in the case of the normal MsgBox() Function of MS-Access too. But, Office Assistant has some solution to this rigid behavior of Message Boxes.

When the Balloon is displayed, you cannot open a Form or Report to check something on it, before clicking the Yes or No Button on the MsgBox because the Mode Property of the Balloon Object is set with default value msoModeModal.

I have not introduced the Mode Property to you in the earlier examples to avoid overcrowding of usage rules. Once you are through with the basics it will be easier to understand other things associated with it better. You have already seen that you can create Message Boxes using Balloon Object of Office Assistant with few lines of Code and display them in style without using these properties.

The Mode Property can be set with three different values to control the behavior of the Balloon Object.

Mode = msoModeModal (default)

This value setting forces the User to dismiss the Balloon by responding to the suggested action before doing anything else, like normal MS-Access MsgBox. You have to click on one of the Buttons (if more than one is showing like OK and Cancel) on the MsgBox to dismiss the Balloon before you are allowed to do anything else.

Mode = msoModeModeless

This value setting allows the User to access other database objects, while the Balloon is active. But, this forces the use of another Property CallBack, to run separate Sub-Routine to do the testing of selection of choices or do different things based on the choice and finally to Close the Balloon Object.

Mode = msoModeAutoDown

This value setting dismisses the Balloon (MsgBox) automatically if you click somewhere else ignoring the Balloon.

The first and last Mode Property value setting and their usages are very clear. But, the second one (msoModeModeless) needs the CallBack Property Value set with the name of a valid Sub-Routine otherwise the Balloon will not work. You cannot load the CallBack Property with an empty string either because that will trigger an Error.

So let us see how we can re-write the earlier Program to understand the usage of Mode Property set with the value msoModeModeless and Callback Property with the name of a Sub-Routine to handle the selection of option displayed in the Menu.

The Modified Code with Mode and CallBack Property Settings and the sample Code for the required Sub-Routine MyProcess() is given below:


Public Sub Choices()
Dim bln As Balloon

Set bln = Assistant.NewBalloon
With bln
    .Heading = "Report Options"
    .Icon = msoIconAlertQuery
    .Button = msoButtonSetNone
    .labels(1).text = "Print Preview."
    .labels(2).text = "Print. "
    .labels(3).text = "Pivot Chart. "
    .BalloonType = msoBalloonTypeButtons
    .text = "Select one of  " & .labels.Count & " Choices? "
    .mode = msoModeModeless
    .Callback = "myProcess"
    .Show
End With

End Sub


Sub MyProcess(bln As Balloon, lbtn As Long, lPriv As Long)
Assistant.Animation = msoAnimationPrinting
Select Case lbtn
    Case 1
        DoCmd.OpenReport "MyReport", acViewPreview
    Case 2
        DoCmd.OpenReport "MyReport", acViewNormal
    Case 3
        DoCmd.OpenReport "MyReport", acViewPivotChart
End Select
    bln.Close
End Sub

The CallBack Property is set with the Sub-Routine name myProcess. When the User clicks on one of the Options from the displayed MsgBox the MyProcess() Sub-Routine is called by the Balloon and passes the required Parameter Values.

There are three parameters passed to the Sub-Routine when called:

The Balloon Object bln.

A Long Integer type value lbtn (BalloonTypeButton) identifying the Option clicked.

A Long Integer type value lPriv (Private) uniquely identifying the Balloon that called the Sub-Routine, if there are more than one Balloon active in memory at the same time.

NB: There is no such thing as collection of Balloon Objects. But, you can create an Array of Variables with Balloon Object, define different Property Settings for each of them and .Show them with their respective index numbers in Programs when you need them to appear.

The lbtn Variable will have the value of User's choice. This is tested in the Sub-Routine and runs the Docmd.OpenReport action within the Select Case …End Select Statements.

The Assistant.Animation = msoAnimationPrinting line is placed in the Sub-Routine, rather than in the main Program as part of the Balloon Object Property setting, to animate the printing action only after the User makes a selection from the displayed Menu otherwise the printing animation will run before the selection of choices.

The bln.close statement dismisses the MsgBox.

Next week we will learn how to use the CheckBoxes().Text Property Values of the Balloon Object to display a Menu with Check-Boxes in MsgBox.

Network and Report Page Setup-2
Network and Report Page Setup
Filter by Character and Sort
Animating Label on Search Success
Form Background with Gradient Color

Office Assistant and MsgBox Menus

noreply@blogger.com (a.p.r. pillai) — Wed, 19 Aug 2009 14:55:00 +0000

In last Week's Article: Color and Picture in Message Box we have seen a method to use Office Assistant quickly to display a Message Box with formatted text. We are not going to discuss further on the formatting part but I have a general feeling that Readers would like to know how this simple method can be used to obtain responses from Users, out of several options presented to them, and do different things based on their selection of choices.

I have already covered this topic by creating Functions like MsgOK(), MsgYN(), MsgOKCL() etc., with the use of Office Assistant. These can be called with only the Message Text Value alone or Message Text and Title Values as Parameters, from anywhere within the Application like the built-in Function MsgBox(). I made an attempt to simplify the usage of Office Assistant through the above mentioned Functions and others, which otherwise needs several property values to be passed to the Office Assistant’s Balloon Object for displaying.

But, in the simplification process the method used in those Functions is not fully understood by several readers.

The Links to those earlier posts are given below for reference:

Message Box with Office Assistant

Message Box with Options Menu

Office Assistant with CheckBox Menu

In the example Code presented in last week’s Post: Color and Picture in Message Box we came across several Properties of the Balloon Object of Office Assistant that can be set with values before the Message Box is displayed.

We are going to work with these properties directly, so that it is easy to understand their usage, rather than passing values for them through the Parameter List in the function definition.

Following are some of these properties:

Animation

Icon

Heading

Text

BalloonType

Button

NB: If you have not already attached the Microsoft Office Object Library to your Database, to try out the examples given here, then do that by following the procedure given below.

Press Alt+F11 to display the VBA Code Window (or Tools - ->Macro- ->Visual Basic Editor).

Select References from Tools Menu.

Find Microsoft Office Object Library in the Available List and put a check mark to select it.

Click OK to close the Dialog Box.

The value for Animation alone has about thirty five different choices which are defined as Constants in the Microsoft Office Object Library. The constant values for Balloon Properties Animation, Button, Icon and BalloonType are given below for reference:

Animation	Icon
msoAnimationAppear msoAnimationBeginSpeaking msoAnimationCharacterSuccessMajor msoAnimationCheckingSomething msoAnimationDisappear msoAnimationEmptyTrash msoAnimationGestureDown msoAnimationGestureLeft msoAnimationGestureRight msoAnimationGestureUp msoAnimationGetArtsy msoAnimationGetAttentionMajor msoAnimationGetAttentionMinor msoAnimationGetTechy msoAnimationGetWizardy msoAnimationGoodbye msoAnimationGreeting msoAnimationIdle msoAnimationListensToComputer msoAnimationLookDown msoAnimationLookDownLeft msoAnimationLookDownRight msoAnimationLookLeft msoAnimationLookRight msoAnimationLookUp msoAnimationLookUpLeft msoAnimationLookUpRight msoAnimationPrinting msoAnimationRestPose msoAnimationSaving msoAnimationSearching msoAnimationSendingMail msoAnimationThinking msoAnimationWorkingAtSomething msoAnimationWritingNotingSomething	msoIconAlert msoIconAlertCritical msoIconAlertInfo msoIconAlertQuery msoIconAlertWarning msoIconNone msoIconTip
Button	BalloonType
msoButtonSetAbortRetryIgnore msoButtonSetBackClose msoButtonSetBackNextClose msoButtonSetBackNextSnooze msoButtonSetCancel msoButtonSetNextClose msoButtonSetNone msoButtonSetOK msoButtonSetOkCancel msoButtonSetRetryCancel msoButtonSetSearchClose msoButtonSetTipsOptionsClose msoButtonSetYesAllNoCancel msoButtonSetYesNo msoButtonSetYesNoCancel	msoBalloonTypeButtons msoBalloonTypeBullets msoBalloonTypeNumbers

Animation and Icon properties are always set with one of the above values based on what we are trying to convey to the User. By default the OK button will appear. If any other Button or Buttons Group is required then the Button Property must be set with one of the above values. The BalloonType is used with Labels Property only. We will look into the Labels property at the later part of this Article.

I am sure when you go through these simple straightforward examples you will be better informed about the usage of Office Assistant, its methods and will start using them in your Applications.

I will reproduce the Code here with simple changes, which we have seen in last week’s Article, and go through it before we make changes in them for our new examples.


Public Sub MyMsgBox()
Dim strMsg As String
Dim strTitle As String

strTitle = "Assistant Test"
strMsg = "Wecome to MS-Access Tips and Tricks"

With Assistant.NewBalloon
    .Icon = msoIconAlertInfo
    .Animation = msoAnimationGetAttentionMajor
    .Heading = strTitle
    .text = strMsg
    .Show
End With

End Sub

Press Alt+F11 to display the VBA Editing Window. Select Module from Insert Menu to create a new Standard VBA Module. Copy and Paste the above Code into the Module. Click somewhere in the middle of the Code and Press F5 to Run it.

In the above example the .Show() method displays the Message Box after setting the other Property Values. The Text property value shows the body text of the Message Box and Heading is the Title Text in Bold letters. The Animation property can be set with one of the 35 different options given above. The Icon Property value we have changed to Information type here.

If we want to obtain the responses of the User to do different things then we need to bring in the Button Property into the Code. Let us say if the User needs to proceed with the report preparation process then she must click the OK Button otherwise Cancel Button. To evaluate the response received from the User and to take action accordingly we must write code for that further down in the Routine.

Let us see how we can do this with changes to the above Code. The modified program is given below:


Public Sub MyMsgBox ()
Dim strMsg As String
Dim strTitle As String
Dim R As Long

Title = "Assistant Test"
msgTxt = "Proceess Weekly Reports...?"

With Assistant.NewBalloon
    .Icon = msoIconAlertQuery
    .Animation = msoAnimationGetAttentionMajor
    .Button = msoButtonSetOkCancel
    .Heading = strTitle
    .text = strMsg
   R = .Show
End With

If R = -1 Then 'User Clicked OK Button
    DoCmd.RunMacro "ReportProcess"
End If
End Sub

Compare the changes made in the new Code with the earlier one to find the difference.

If the User clicked the OK Button (-1 is returned in Variable R, Cancel=-2) then the ReportProcess Macro is run otherwise the Program ends doing nothing.

We can give different choices to the User in the form of a Menu with the use of Labels Property and perform the actions based on User’s response. See the example code given below:


Public Sub Choices()
Dim R As Long
Dim bln As Balloon

Set bln = Assistant.NewBalloon
With bln
    .Heading = "Report Options"
    .Icon = msoIconAlertQuery
    .Button = msoButtonSetNone
    .labels(1).text = "Print Preview."
    .labels(2).text = "Print."
    .labels(3).text = "Pivot Chart."
    .BalloonType = msoBalloonTypeButtons
    .text = "Select one of " _
       & .labels.Count & " Choices?"
    R = .Show
End With

Select Case R
    Case 1
        DoCmd.OpenReport "MyReport", acViewPreview
    Case 2
        DoCmd.OpenReport "MyReport", acViewNormal
    Case 3
        DoCmd.OpenReport "MyReport", acViewPivotChart
End Select

End Sub

Note: You may copy and paste the Code into the VBA Module and modify it with appropriate changes before attempting to Run it.

The dimension of the Labels() Property Value can be up to a maximum of 5 only. The BalloonType Value msoBalloonTypeButtons allows the User to click on one of the Options to select it and the Index value of the item clicked is returned in Variable R. We have set the Value Button = msoButtonSetNone to remove the OK Button from appearing so that the User will click only on one of the Options displayed.

There are two more BalloonType Property values available: msoBalloonTypeBullets and msoBalloonTypeNumbers. These are not selectable, like msoBalloonTypeButtons, and used only for displaying information.

Compare the following Code with the earlier one to see the difference in changed Property Values.


Public Sub InfoDisplay()
Dim bln As Balloon

Set bln = Assistant.NewBalloon
With bln
    .Heading = "Reminder"
    .Icon = msoIconAlertInfo
    .labels(1).text = "MIS Reports."
    .labels(2).text = "Trial Balance."
    .labels(3).text = "Balance Sheet."
    .BalloonType = msoBalloonTypeBullets
    .text = "Monthly Reports for User Departments"
    .Button = msoButtonSetOK
    .Show
End With

Sample Images with BalloonType Property Changes are given below:

We will continue this discussion next week to see more ways to use the Office Assistant with Labels and CheckBoxes.

Network and Report Page Setup
Filter by Character and Sort
Animating Label on Search Success
Form Background with Gradient Color
MS-Access and Reference Library